use strict;
use warnings;

use Test::More 'tests' => 16;
use Scalar::Util qw( blessed reftype );

my $side_effect = 0;

package OverloadCode;
use overload '&{}' => sub { $side_effect = 1; sub {} };

package main;

sub is_code_eval {
    no warnings qw( void uninitialized );
    return '' ne ref $_[0] && eval { defined &{$_[0]} };
}
sub is_code_util {
    my $suspected_code = shift;

    return 0 if '' eq ref $suspected_code;
    return 1 if 'CODE' eq reftype $suspected_code;
    if (    blessed $suspected_code
         && overload::Method( $suspected_code, '&{}' ) ) {
        return 1;
    }
    return 0;
}

sub real_sub { $side_effect = 1 }

check_method( \&is_code_util, 'utils' );
check_method( \&is_code_eval, 'eval' );

sub check_method {
    my ( $tester, $name ) = @_;

    $side_effect = 0;
    my $sub_ref = sub { $side_effect = 1 };
    my $overcode = bless {}, 'OverloadCode';
    my $undef;

    ok( $tester->( \&real_sub ),   "$name: real sub ref is code" );
    ok( $tester->( $sub_ref   ),   "$name: lexical sub ref is code" );
    ok( ! $tester->( $undef   ),   "$name: undef is code" );
    ok( ! $tester->( 'string' ),   "$name: string is not code" );
    ok( ! $tester->( 'real_sub' ), "$name: real_sub as string is not code" );
    ok( $tester->( $overcode ),    "$name: overloaded reference is code" );
    # this test fails for the eval method
    ok( ! $side_effect,            "$name: no side effect" );
    is( $undef, undef,             "$name: \$undef is still undef" );
}