#!/usr/bin/perl -w
use strict;
use XML::Twig;

my %links = (
             "img" => "/images/Orange_Test.jpg",
             "alt" => "Orange Test Image",
             "name" => "Orange Test Image",
             "title" => "Hello World. This is a test page. Please click here for more information.",
             "url" => "http://localhost/orange_test.htm",
             "dcr" => "/templatedata/test2123/test/orange_test",
            );
my $path = "/orange_test.htm";
my $file = "s1.xml";

my $x = XML::Twig::Elt->new(
                            record => map {
                                XML::Twig::Elt->new( $_ => $links{$_})
                            }
                            sort keys %links)
    ->set_att("path",$path);

my $twig = XML::Twig->new(pretty_print => 'indented');
if(!-s $file) {
    $twig->set_root(
                    XML::Twig::Elt->new(data => $x)
                   );
} else {
    my $item_pasted;

    $twig->setTwigHandlers(
                           {
                               record => sub {
                                   my( $twig, $record)= @_;
                                   unless ($item_pasted) {
                                       my $rpath = $record->att('path');
                                       if ($rpath eq $path) {
                                           $x->replace($record);
                                           $item_pasted=1;
                                           return
                                       }
                                   }
                               },
                           }
                          );

    $twig->parsefile($file);

    $x->paste('last_child',$twig->root) unless($item_pasted);

}

{
    open (my $xfile, ">", $file) or die "Can't save to $file: $!";
    $twig->print(\*$xfile);
}