#! /usr/bin/perl
use strict;
use warnings;
use DBI;

my $dbh = DBI->connect( 'DBI:CSV:f_dir=.' ) or die "cannot connect: " . $DBI::errstr;

sub _get_param_fieldnames {

    my %field;

    my $sth = $dbh->prepare( 'SELECT param_id,name FROM x_param' )
        or die "cannot prepare: " . $dbh->errstr;

    $sth->execute or die $dbh->errstr;

    while ( my $row = $sth->fetchrow_arrayref ) {
        $field{ $row->[0] } = $row->[1];
    }

    $sth->finish;

    return \%field;
}

sub _get_object_entries {
    my %object;

    my $sth = $dbh->prepare( 'SELECT * FROM x_object' )
        or die "cannot prepare: " . $dbh->errstr;

    $sth->execute or die $dbh->errstr;

    while ( my $row = $sth->fetchrow_arrayref ) {
        $object{ $row->[0] }->{ $row->[1] } = $row->[2];
    }

    $sth->finish;

    return \%object;
}


# output stuff
{
    my $field_by  = _get_param_fieldnames();
    my $object_by = _get_object_entries();

    local $, = ',';
    local $\ = "\n";

    # create csv output; check for proper modules

    print 'OBJECT_ID', map { $field_by->{$_} }  sort { $a <=> $b } keys %$field_by;

    for my $oid ( keys %$object_by ) {

        my @param_values;

        for my $pid ( sort { $a <=> $b } keys %$field_by ) {
            push @param_values, exists $object_by->{$oid}->{$pid} ? $object_by->{$oid}->{$pid} : '';
        }

        print $oid, @param_values;
    }
}

$dbh->disconnect;

__END__