my $w= "\s\0";      # Whitespace
my $s= "\x14\0";    # Separator
my $q= "\xFE\0";    # Quote / escape
my $c= "..";        # Character
# Versions we can apply modifiers to:
my $W= "(?:$w)";
my $S= "(?:$s)";
my $Q= "(?:$q)";
my $C= "(?:$c)";

$/= "\r\0\n\0";
while(  <CSV>  ) {
    my @row;
    my $end= 'none';
    while(
        m{
            \G                      # Don't skip any characters
            $W*(?!$w)               # Ignore whitespace outside quotes
            (?:                     # Either quoted value of bare value:
                $q(                 # Opening quote, keep quoted value as $1
                    (?:
                        $q$q        # An escaped quote
                      | (?!$q)$c    # Or a non-quote
                    )*              # Zero or more characters per value
                )$q(?!$q)           # Closing quote (not escaped)
              | (                   # Capture the bare value as $2
                    (?:
                        (?!$s|$q)$c # A non-separator, non-quote character
                    )+              # One or more 'bare' characters
                )(?<!$w)            # Don't backtrack
              | ( )                 # An empty field as $3
            )   # Separate "empty field" case required by prior (?<!$w)
            $W*
            ( $s | \z )             # Track field terminator in $4
        }xsg
    ) {
        $end= $4;
        my( $quoted, $bare, $empty )= ( $1, $2 );
        if(  defined $empty  ) {
            push @row, undef;   # Or whatever you want 'empty' to mean
        } elsif(  defined $quoted  ) {
            $quoted =~ s/$q$q/$q/g;
            push @row, $quoted;
        } else {
            push @row, $bare;
        }
    }
    if(  '' ne $end  ) {    # We didn't reach \z
        warn "Skipping malformed line ($.).\n";
        next;
    }
    # Do something with @row, which has values as array of byte strings
}