#!/usr/bin/perl

use strict;
use warnings;
use Benchmark qw(cmpthese);
use Socket qw(inet_aton inet_ntoa);

use Sort::Key::IPv4 qw(ipv4sort ipv4_to_uv);
use Sort::Key::Radix qw(ukeysort);

chomp( my @ips=(<>) );

cmpthese(-10,
    {
        inet_grt => sub { 
            my @sorted = map { inet_ntoa $_ }
                sort { $a cmp $b }
                map { inet_aton $_ } @ips;
        },
        inet_grt2 => sub { 
            my @sorted = map { unpack 'x4A*' }
                sort { $a cmp $b }
                map { pack('A4A*', inet_aton($_), $_) } @ips;
        },
        inet_orc => sub { 
            my @sorted = sort by_ip @ips;
        },
        splitwise => sub {
            my @sorted =
            map $_->[0],
            sort {
                $a->[1] <=> $b->[1] or
                $a->[2] <=> $b->[2] or
                $a->[3] <=> $b->[3] or
                $a->[4] <=> $b->[4]
            }
            map [$_, split /\./], @ips;
        },
        split_int => sub {
            my @sorted = map { join '.', unpack("CCCC", pack("N",$_)) }
                sort { $a <=> $b }
                map { unpack("N",pack("CCCC",split /\./)) } @ips;
        },
        naive => sub {
            my @sorted = sort {
                my @a = split /\./, $a;
                my @b = split /\./, $a;
                $a[0] <=> $b[0] or
                $a[1] <=> $b[1] or
                $a[2] <=> $b[2] or
                $a[3] <=> $b[3]
                } @ips;
        },
        sk => sub {
	    my @sorted = ipv4sort @ips;
	},
        skr => sub {
            my @sorted = &ukeysort(\&ipv4_to_uv, @ips);
	}

    });

{
    my %cache;
    sub by_ip
    {
        my $orc_a = ($cache{$a} ||= inet_aton($a));
        my $orc_b = ($cache{$b} ||= inet_aton($b));
        $orc_a cmp $orc_b;
    }
}