#!/usr/bin/perl

use strict;
use warnings;

use Benchmark ':hireswallclock';
use DB_File ();
use DBI ();

my $DB_FILE;
my $DBH_SQLITE;

my @CHARS       = ( 'A' .. 'Z', 'a' .. 'z', 0 .. 9, qw( ! @ $ % ^ & * ) );
my $NUM_RECORDS = 50_000;

setup_dbfile();
setup_sqlite();

Benchmark::cmpthese(
    10,
    {
        'berkeley' => \&benchmark_dbfile,
        'sqlite'   => \&benchmark_sqlite
    }
);

untie %$DB_FILE;


sub benchmark_dbfile {

    my $value = 0;

    while ( $value < $NUM_RECORDS ) {

        my $key = join( '', @CHARS[ map { rand @CHARS } ( 1 .. 5 ) ] );

        if ( exists $DB_FILE->{$key} ) {
            $DB_FILE->{$key} .= ",$value";
        }
        else {
            $DB_FILE->{$key} = $value;
        }

        $value++;

    }

    return;

}

sub benchmark_sqlite {

    my $sth = $DBH_SQLITE->prepare( 'INSERT INTO benchmark ( key, value ) VALUES ( ?, ? )' );

    $DBH_SQLITE->begin_work;

    my $value = 0;

    while ( $value < $NUM_RECORDS ) {
        my $key = join( '', @CHARS[ map { rand @CHARS } ( 1 .. 5 ) ] );
        $sth->execute( $key, $value );
        $value++;
    }

    $DBH_SQLITE->commit;

    return;

}


sub setup_sqlite {

    $DBH_SQLITE = DBI->connect(
        'dbi:SQLite:dbname=benchmark.sqlite',
        '',
        '',
        {
            'RaiseError' => 1
        }
    );

    if ( ! $DBH_SQLITE->tables( undef, undef, 'benchmark', 'TABLE' ) ) {
        $DBH_SQLITE->do( 'CREATE TABLE benchmark ( key VARCHAR, value INTEGER )' ); 
    }

    return;

}

sub setup_dbfile {

    my %data;
    tie %data, 'DB_File', 'berkeley.db' or die "$!";
    $DB_FILE = \%data;

    return;

}