#!/usr/bin/perl
use warnings;
use strict;
use Tk;
use Tk::DragDrop;
use Tk::DropSite;

my %tk;

$tk{lbfont} = '{Helvetica} 14';

my $trashcan = '
R0lGODlhFgAZAPcAAAAAAIAAAACAAICAAAAAgIAAgACAgMDAwMDcwKbK8EAgAGAgAIAgAKAgAMAg
AOAgAABAACBAAEBAAGBAAIBAAKBAAMBAAOBAAABgACBgAEBgAGBgAIBgAKBgAMBgAOBgAACAACCA
AECAAGCAAICAAKCAAMCAAOCAAACgACCgAECgAGCgAICgAKCgAMCgAOCgAADAACDAAEDAAGDAAIDA
AKDAAMDAAODAAADgACDgAEDgAGDgAIDgAKDgAMDgAODgAAAAQCAAQEAAQGAAQIAAQKAAQMAAQOAA
QAAgQCAgQEAgQGAgQIAgQKAgQMAgQOAgQABAQCBAQEBAQGBAQIBAQKBAQMBAQOBAQABgQCBgQEBg
QGBgQIBgQKBgQMBgQOBgQACAQCCAQECAQGCAQICAQKCAQMCAQOCAQACgQCCgQECgQGCgQICgQKCg
QMCgQOCgQADAQCDAQEDAQGDAQIDAQKDAQMDAQODAQADgQCDgQEDgQGDgQIDgQKDgQMDgQODgQAAA
gCAAgEAAgGAAgIAAgKAAgMAAgOAAgAAggCAggEAggGAggIAggKAggMAggOAggABAgCBAgEBAgGBA
gIBAgKBAgMBAgOBAgABggCBggEBggGBggIBggKBggMBggOBggACAgCCAgECAgGCAgICAgKCAgMCA
gOCAgACggCCggECggGCggICggKCggMCggOCggADAgCDAgEDAgGDAgIDAgKDAgMDAgODAgADggCDg
gEDggGDggIDggKDggMDggODggAAAwCAAwEAAwGAAwIAAwKAAwMAAwOAAwAAgwCAgwEAgwGAgwIAg
wKAgwMAgwOAgwABAwCBAwEBAwGBAwIBAwKBAwMBAwOBAwABgwCBgwEBgwGBgwIBgwKBgwMBgwOBg
wACAwCCAwECAwGCAwICAwKCAwMCAwOCAwACgwCCgwECgwGCgwICgwKCgwMCgwOCgwADAwCDAwEDA
wGDAwIDAwKDAwP/78KCgpICAgP8AAAD/AP//AAAA//8A/wD//////yH5BAEAAP8ALAAAAAAWABkA
BwjUAP8JHEiwoMGDCBMeBMAQgMKCDaVIJAUgicWEDe0h2CRlEykp9w7cY2gQwD179v4hOMByCwBS
LO9RLJgE5gEEKFGSIiWT1BYpDgm+BIAg5L2jO5NKDCrUI8uiR49u2pKEqdCQmzzuzOpx6UKY9liK
TMqx6tcD9o4e4Hkvq9eSYHmu3Snlo1m4aOUqLWt14Mu8IfdKuQsxbmC6fM/a04t4cF+Bfxcf/pgY
r+S5Hz8CXRjy8l6qj/8BQPtPLE9SWUEjrBpyJdKfmxUCkDh4MOGHuHPjDggAOw==
';

$tk{mw} = MainWindow->new;

$tk{buttonframe} = $tk{mw}->Frame->pack( -pady => 3 );

$tk{load} = $tk{buttonframe}->Button(
    -text    => 'Select (Multiple) Files',
    -command => sub { $tk{listbox}->insert( 'end', getFiles() ) },
)->grid( -row => 1, -column => 1 );

$tk{clear} = $tk{buttonframe}->Button(
    -text    => 'Clear All',
    -command => sub { $tk{listbox}->delete( 0, 'end' ) },
)->grid( -row => 1, -column => 2 );

$tk{trash} = $tk{buttonframe}->Label(
    -image => $tk{mw}->Photo(
        -format => 'gif',
        -data   => $trashcan,
    ),
)->grid( -row => 1, -column => 3 );

$tk{process} = $tk{buttonframe}->Button(
    -text    => 'Process Files',
    -command => sub { print join " + ", $tk{listbox}->get( 0, 'end' ); },
)->grid( -row => 1, -column => 4 );

$tk{lbframe} = $tk{mw}->Frame->pack(
    -expand => 1,
    -fill   => 'both',
    -anchor => 'nw'
);

$tk{listbox} = $tk{lbframe}->Scrolled(
    'Listbox',
    -selectmode => 'single',
    -scrollbars => 'ose',
    -font       => $tk{lbfont},
  )->pack(
    -expand => 1,
    -fill   => 'both',
    -padx   => 5,
    -pady   => 5,
  );

my $dnd_token = $tk{listbox}->DragDrop(
    -event        => '<B1-Motion>',
    -sitetypes    => [qw/Local/],
    -startcommand => \&DragStart,
);

$tk{listbox}->DropSite(
    -droptypes   => [qw/Local/],
    -dropcommand => [ \&Drop, $tk{listbox}, $dnd_token ],
);

MainLoop;

sub DragStart {
    my ($token) = @_;
    my $site    = $token->parent;
    my $e       = $site->XEvent;
    my $idx     = $site->index( '@' . $e->x . ',' . $e->y );
    if ( defined $idx ) {
        $token->configure( -text => $site->get($idx), -font => $tk{lbfont} );
        $site->delete($idx);
        my ( $X, $Y ) = ( $e->X, $e->Y );
        $token->MoveToplevelWindow( $X, $Y );
        $token->raise;
        $token->deiconify;
        $token->FindSite( $X, $Y, $e );
    }
}

sub Drop {
    my ( $site, $token ) = @_;
    my $text    = $token->cget('-text');
    my $y       = $site->pointery - $site->rooty;
    my $nearest = $site->nearest($y);
    if ( defined $nearest ) {
        my @xy = $site->bbox($nearest);
        if ( @xy and $xy[1] + $xy[3] > $y ) {
            $site->insert( $nearest, $text );
        }
        else {
            $site->insert( 'end', $text );
        }
    }
}

sub getFiles {
    my @types =
      ( [ "3d Files", '.3d' ], [ "Excel Files", '.xls' ],
        [ "All files", '*' ] );
    my @files = $tk{mw}->getOpenFile(
        -filetypes        => \@types,
        -defaultextension => '.3d',
        -title            => 'Hold Down Ctrl Key To Select Multiple Files',
        -multiple         => 1,
    );
    return @files;
}