#!/usr/bin/perl
use strict;
use warnings;

my %graph = (
      read145404_1 => [qw/read231054_2 read250449_2/],
      read231054_2 => [qw/read359463_1 read691358_1 read937013_1/],
      read250449_2 => [qw/read359463_1 read691358_1 read937013_1/],
);

my %node_to_int = convert_node_to_int(\%graph);

my $routes = find_paths('read145404_1', 'read691358_1', \%graph);
print "$_\n" for @$routes;

sub find_paths {
    my ($beg, $end, $graph) = @_;
    my (@work, @solution);
    for (@{$graph->{$beg}}) {
        if ($_ eq $end) {
            push @solution, "$beg->$end";
            next;
        }
        my $seen = '';
        vec($seen, $node_to_int{$_}, 1) = 1;
        vec($seen, $node_to_int{$beg}, 1) = 1;
        push @work, ["$beg->$_", $_, $seen];
    }
    while (@work) {
        my $item = pop @work;
        my ($path, $curr, $seen) = @$item;
        for my $node (@{$graph->{$curr}}) {
            my $bit = $node_to_int{$node};
            next if vec($seen, $bit, 1);
            if ($node eq $end) {
                push @solution, "$path->$end";
                next;
            }
            my $new_seen = $seen;
            vec($new_seen, $bit, 1) = 1;
            push @work, ["$path->$node", $node, $new_seen];
        }
    }
    return \@solution;
}

sub convert_node_to_int {
    my ($graph) = @_;
    my ($n, %lookup);
    for my $node (keys %$graph) {
        $lookup{$node} = $n++ if ! defined $lookup{$node};
        for (@{$graph->{$node}}) {
            $lookup{$_} = $n++ if ! defined $lookup{$_};
        }
    }
    return %lookup;
}