#!/usr/bin/perl -w

use strict;
use vars qw($opt_h);
use Getopt::Std;

getopts('h');
my @dir = ([0,-1],[1,0],[0,1],[-1,0]);
my (@map, @mark, @dist);
my (%mouse, %cheese);
my $poss = 1;

# initialize map
while(<>) {
    chomp;
    push @map, [map { tr/#// } split //];
    if (/M/) {
        $mouse{x} = length($`);
        $mouse{y} = $. - 1;
    }
    if (/C/) {
        $cheese{x} = length($`);
        $cheese{y} = $. - 1;
    }
}

# init dist
foreach my $row (0..$#map) {
    $dist[$row] = [map {($_ - $cheese{x})**2 + ($row - $cheese{y})**2} 0..$#{$map[$row]}];
}

sub find_cheese {
    my ($x, $y) = @_;
    return if not $poss; 

    $mark[$x][$y] = 1;  
    print "X = $x, Y = $y\n";
    $poss = 0 if ($x == $cheese{x} && $y == $cheese{y});

    for ($opt_h? 
        sort { $dist[$y + $a->[1]][$x + $a->[0]] <=> $dist[$y + $b->[1]][$x + $b->[0]] } @dir 
        : @dir) {
        !$map[$y + $_->[1]][$x + $_->[0]] &&
        !$mark[$x + $_->[0]][$y + $_->[1]] &&
        find_cheese($x + $_->[0], $y + $_->[1]);
    }
}

find_cheese(@mouse{'x','y'});
print "Cheese found!!\n" if not $poss;