#!/usr/bin/perl -w
#<UnusedGrp.pl> Find unused Groups in /etc/group

my $GROUPfile="/etc/group";
my $gfpid = open(GFILE, "<$GROUPfile") or die "$GROUPfile File Not Found: $!\n";
my $PASSWD="/etc/passwd";
my $pfpid = open(PFILE, "<$PASSWD") or die "$PASSWD File Not Found: $!\n";
@PWLINES = <PFILE>;

while (my $line = <GFILE>) {
   @GRP = split(/:/, $line);
   if (length($GRP[3]) < 2){
     print "$GRP[0]:$GRP[2] is zero length\n";

     my @GIDs = map { (split /:/)[3] } @PWLINES;
     my $seen = 0;
     for my $GID (@GIDs) {
        if ($GID == $GRP[2]) {
           $seen = 1
        }
     }
     if (not $seen) {
        print "$GRP[0]:$GRP[2] has no users\n";
     }
   }
}

##</code><code>##

#!/usr/bin/perl -w
#<UnusedGrp.pl> Find unused Groups in /etc/group
use strict;

my $GROUPfile="/etc/group";
my $gfpid = open(GFILE, "<", $GROUPfile) or die "$GROUPfile Open failed: $!\n";
my $PASSWD="/etc/passwd";
my $pfpid = open(PFILE, "<", $PASSWD) or die "$PASSWD Open failed: $!\n";

my %gids;
while (my $line = <PFILE>) {
    my @user = split /:/, $line;
    $gids{$user[3]}++;
}


while (my $line = <GFILE>) {
   my @GRP = split(/:/, $line);

   if (length $GRP[3] > 1) { # $GRP[0]:$GRP[2] is not zero length
      next;
   }

   if ($gids{$GRP[2]}) { # GID found in passwd
      next;
   }

   print "$GRP[0] has no users and no GID references\n"
}

##</code><code>##

#!/usr/bin/perl -w
#<UnusedGrp.pl> Find unused Groups in /etc/group
use strict;

my $GROUPfile="/etc/group";
my $PASSWD="/etc/passwd";

open my $gh, "<", $GROUPfile or die "$GROUPfile Open failed: $!\n";
open my $ph , "<", $PASSWD or die "$PASSWD Open failed: $!\n";

my %gids = map { (split /:/)[3] => 1 } <$ph>;

while (<$gh>) {
    my @fields = split /:/;

    next if length $fields[3] > 1;
    next if $gids{$fields[2]};
    print "$fields[0] has no users and no GID references\n"
}