From LWP::Protocol..

sub new
{
    my($class) = @_;

    my $self = bless {
        'timeout' => 0,
        'parse_head' => 1,
    }, $class;
    $self;
}      

sub create
{
    my $scheme = shift;
    my $impclass = LWP::Protocol::implementor($scheme) or
        Carp::croak("Protocol scheme '$scheme' is not supported");

    # hand-off to scheme specific implementation sub-class
    return $impclass->new($scheme);
}   

sub implementor
{
    my($scheme, $impclass) = @_;

    if ($impclass) {
        $ImplementedBy{$scheme} = $impclass;
    }
    my $ic = $ImplementedBy{$scheme};
    return $ic if $ic;

    return '' unless $scheme =~ /^([.+\-\w]+)$/;  # check valid URL schemes
    $scheme = $1; # untaint
    $scheme =~ s/[.+\-]/_/g;  # make it a legal module name

    # scheme not yet known, look for a 'use'd implementation
    $ic = "LWP::Protocol::$scheme";  # default location
    $ic = "LWP::Protocol::nntp" if $scheme eq 'news'; #XXX ugly hack
    no strict 'refs';
    # check we actually have one for the scheme:
    unless (@{"${ic}::ISA"}) {
        # try to autoload it
        eval "require $ic";
        if ($@) {
            if ($@ =~ /Can't locate/) { #' #emacs get confused by '
                $ic = '';
            } else {
                die "$@\n";
            }
        }
    }
    $ImplementedBy{$scheme} = $ic if $ic;
    $ic;
}