#! perl -slw
use strict;
use Data::Dump qw[ pp ];

sub dhm2int {
    my( $d, $h, $m ) = unpack '(A2)*', $_[0];
    return ( ( $d - 1 ) * 24 + $h ) * 60 + $m;
}

sub int2dhm {
    sprintf "%02d%02d%02d", int($_[0]/1440)+1, int($_[0]/60)%24, $_[0]%60;
}

#my @data = (
#    ['010000','010010',2],['010200','010210',5],['012359','020001',3],
#    ['010005','010015',1],['010207','010211',4]
#);

my @data = map[ split ], <>;

my @expd = map {
    my $in = $_;
    my $s = dhm2int( $in->[ 0 ] );
    my $e = dhm2int( $in->[ 1 ] );

    my @out;
    while( int( $s / 1440 ) != int( $e / 1440 ) ) {
        my $newe = ( int( $s / 1440 ) +1 ) * 1440 -1;
        push @out, [ $s, $newe, $in->[2] ];
        $s = $newe +1;
    }
    ( @out, [ $s, $e, $in->[2] ] );
} @data;

my( @tally );
for my $e ( 0 .. $#expd ) {
    my $r = $expd[ $e ];
    for my $i ( $r->[ 0 ] .. $r->[ 1 ] ) {
        if( !defined( $tally[ $i ] ) or $tally[ $i ] > $r->[ 2 ] ) {
            $tally[ $i ] = $r->[ 2 ];
        }
    }
}

my @res;
my $i = 0;
while( $i < $#tally ) {
    ++$i until defined $tally[ $i ];
    my $val = $tally[ $i ];
    my $start = $i++;
    ++$i while defined( $tally[ $i ] ) and $tally[ $i ] == $val and $i % 1440;
    my $end = $i - 1;
    push @res, [ int2dhm( $start ), int2dhm( $end ), $val ];
}

pp \@res;