use strictures;
use XML::LibXML;
use open qw(:std :utf8);
use YAML;

my $dom = XML::LibXML->load_html( string => do { local $/; <DATA> },
                                  keep_blanks => 0 );

my @advisories;
# Only select <c><p></c>s that have a PDF link inside.
for my $p ( map { $_->parentNode } $dom->findnodes(q{//p//a[contains(@href,'.pdf')]}) )
{
    my %tmp;
    for my $kid ( $p->childNodes )
    {
        if ( $kid->nodeName eq "a" )
        {
            $tmp{pdf} = { title => $kid->textContent,
                          href => $kid->getAttribute("href")
            };
        }
        elsif ( not $tmp{pdf} )
        {
            # You'd have to do some shuffling to handle <br/>->\n here.
            $tmp{heading} .= $kid->textContent;
        }
        else
        {
            ( $tmp{date} = $kid->textContent ) =~ s/[)(\n\r]//g;
        }
    }
    s/[\s,]+\Z// for $tmp{heading}, $tmp{date};

    push @advisories, \%tmp;
}

print YAML::Dump(\@advisories);

exit 0;

__DATA__
# YOUR HTML FRAGMENT HERE

##</code><code>##

---
- date: 'March 21, 2011'
  heading: |-
    RealFlex TechnologiesMultiple Vulnerabilities in
    RealFlex RealWin
  pdf:
    href: /control_systems/pdf/ICS-ALERT-11-080-04.pdf
    title: ICS-ALERT-11-080-04
- date: 'April 20, 2011'
  heading: RealFlex RealWin Multiple Vulnerabilities
  pdf:
    href: /control_systems/pdf/ICSA-11-110-01.pdf
    title: ICSA-11-110-01
...