#Anonymous block for scoping
{
    my( @linked_tables,@unlinked_tables) = ();
    
    #-----------------------------------------------------------------------------------------------------
    sub _get_table_relations
    { 
        my( $self,$tables,$conditions ) = @_;

        #prep lists
        @unlinked_tables = keys %$tables;
        @linked_tables = ();
        my @tables_nolinks = ();

        #no relations to be found if there's only one table
        return if scalar( @unlinked_tables ) <= 1;

        # try to find a link for each of the supplied tables
        while( my $table = shift @unlinked_tables )
        {
            next if grep { $table eq $_ } @linked_tables;

            push @tables_nolinks, $table unless $self->_table_relation_helper($table,$conditions);
        }

        csWarn(class=>csErrorClass('CODE_PARAMS'),severity=>csErrorScale('MODERATE'),
               message=>'Could not find relations certain tables in this view.',
               debug=>"tables without relations:".join(',',@tables_nolinks)
              )
        if scalar( @tables_nolinks );

        return 1;
    }
    #-----------------------------------------------------------------------------------------------------
    sub _table_relation_helper
    {
        my ($self,$table,$conditions) = @_;

        foreach my $table2 ( @linked_tables, @unlinked_tables )
        {
            # a link exists
            if( exists $self->{_links}{$table,$table2} )
            {
                #store the conditions of our found relationship with our other conditions
                push @{ $conditions->{axioms} },    ( $self->{_links}{$table,$table2}{op} eq $conditions->{op} and ( $conditions->{op} eq 'and' or $conditions->{op} eq 'or' ))
                                                        ? @{ $self->{_links}{$table,$table2}{axioms} }
                                                        : { %{ $self->{_links}{$table,$table2} } };

                #first check to see if $table2 needs linking
                foreach my $i ( 0 .. $#unlinked_tables )
                {
                    if( $unlinked_tables[$i] eq $table2 )
                    {
                        splice(@unlinked_tables,$i,1);

                        $self->_table_relation_helper($table2,$conditions) unless $table2 =~ /\s/;

                        last; #short circuit the foreach
                    }
                }

                #then add $table to $linked_tables
                push @linked_tables, $table;

                return 1; #short circuit
            }
        }
        return 0;
    }
}