#!/usr/bin/perl
use strict;
use warnings;

sub getline
{
  my $line = <DATA>;
  return undef unless $line;
  chomp $line;
  return $line;
}

my @three = ( &getline(), &getline(), &getline() );
my $line;
do {
  print join("\t",@three),"\n";
  @three = ( $three[1], $three[2], $line = &getline() );
} while($line);
[download]

#!/usr/bin/perl -w

use strict;
use warnings;

my @three;

# Stoke it
chomp ($three[0] = <DATA>);
chomp ($three[1] = <DATA>);

while(!eof(DATA))
{
        chomp ($three[2] = <DATA>);

        # Do stuff to process @three
        print join ("\t", @three), "\n";

        # Rotate
        shift(@three);
}

__DATA__
1
2
3
4
5
6
[download]

• Don't put any "warm up" code inside the loop, put it before the loop. This eliminates the CALL sub-loop, and any associated ambiguity with last.
• Don't name your loops for no reason. In this case, you are using last to escape a single loop, not several in a single call, so it is redundant.
• You're backtracking within the file using seek, which seems a little overkill, since you already have the data in @three. Shuffle it around using array methods instead of reading it again and again needlessly.
• Your use of the ?: operator is, while valid, kind of unfortunate. It is normally used in an inline capacity, such as where there is no room for an if. While it might take more room, using if will make it a lot clearer what you're doing.

Don't name your loops for no reason.

IMHO, there's nothing wrong with naming your loops, especially (but not only) when there are multiple or nested loops in the general vicinity. It just makes things more clear, and more self-documenting.

The last function, by definition, bails out of the loop that it is currently inside. If there was any confusion as to where the last call would be tossing program flow to, a comment might help. The loop label indicates the start of the loop, not the finish, so you have to read backwards to find the label, then scan fowards to find the loop finish point.

Why not this?

while (something())
{
     # Lots of stuff, nested functions, etc.
     last if ($condition);   # Move to Post-Processing
     # Lots more stuff
}

# Post-Processing
more_stuff();
[download]

Instead of:

PROCESS:
while (something())
{
     # Lots of stuff, nested functions, etc.
     last PROCESS if ($condition);
     # Lots more stuff
}

more_stuff();
[download]

If the while() structure was very long, it might be easier to scan for a carefully worded comment.

If you have a reason for putting loop labels in, by all means put them in. All I'm advocating is that there shouldn't be things in a program that are there for no reason.

Or maybe I just don't like Perl programs which feel like:

_10: print "Hello";
_20: goto _10;
[download]

For example, cutting and pasting and altering slightly:

my @buffer; 
{ 
  push @buffer, scalar <IN>; 
  redo unless eof(IN) or @buffer >= 10; 
  ## process @buffer 
  shift @buffer;## [was:] @buffer = (); 
  redo unless eof(IN); 
}
[download]

-- Randal L. Schwartz, Perl hacker

THREE: {
  my @three;
  push @three, scalar(<DATA>) or last THREE for 1..2;
  chomp @three;
  while (<DATA>) {
    chomp;
    push @three, $_;
    print "@three\n";
    shift @three;
  }
}
[download]

It's been a bit of a trick to go through and figure out what the different replies have in common. The most obvious trick (to others, at least!) was $foo = <FH>; which apparently pops a single line off of FH, sticks it in $foo, and updates FH so the next read will return the next line in the file.

I feel pretty silly; I'm used to code like this

while ( $line = <FH> ) { 
  # do stuff to $line
}
[download]

tadman said it best: you could just re-work how you're using Perl. Indeed. I was thinking I needed to read three lines, process them, then skip backwards two lines and repeat the cycle. It seems that everyone else realized I just needed to prime my array by reading two lines, then push a third line onto the array, process the lot, shift the first one off, and start pushing and processing again.

For me the neat part about SOPW and the various answers is finding out which answer (if any) the poster decided to go with. In my case, I'm going with the answer that looks the most like my current code - an adaptation of tadman's response. This isn't based off of benchmarks or how easily I can incorporate the changes into my existing code. Perhaps it just seems closest to my Perl idiolect (awkward pidgin that it is).

#!/usr/bin/perl

use strict;
use warnings;

my @three;

# Stoke it
chomp ($three[0] = <DATA>);
chomp ($three[1] = <DATA>);

while(<DATA>) {
  chomp ($three[2] = $_);

  # Do stuff to process @three
  print join ("\t", @three), "\n";

  # Rotate
  shift(@three);
}

__DATA__
1
2
3
4
5
6
[download]

my @data = (<DATA>);
chomp @data;

my $i = 0;
while($i+2 <= $#data) {
    my @three = @data[$i..$i+2];
    print "@three\n";
    $i++;

  # Do stuff to process @three
    print $_,"\t" for ( @three );
    print("\n\n");
}
[download]