in reply to How do I pass $1 to s///?

Your $1 gets interpolated too early. What you really need is a templating system, but you can use the following in the meanwhile: 

sub foo {
    (my $text = $_[0]) =~ s/$_[1]/eval $_[2]/e;
    print $text;
}

foo("This is test 1\n", qr/test (.*)/, '"fish $1"');

[download]

(Insert notice of hazards of using eval EXPR here.)

Replies are listed 'Best First'.
Re^2: How do I pass $1 to s///?
by Anonymous Monk on Jan 06, 2006 at 19:19 UTC
    No need to use eval, I'd prefer one of... 
    sub foo { (my $text = $_[0]) =~ s/$_[1]/$_[2]->($1)/e;
          print $text; }

foo("This is test 1\n", qr/test (.*)/, sub{"fish $_[0]"});

    [download]
    ...or... 
    sub foo { (my $text = $_[0]) =~ s/$_[1]/$_[2]->()/e;
          print $text; }

foo("This is test 1\n", qr/test (.*)/, sub{"fish $1"});

    [download]
[reply]
[d/l]
[select]
      Nice, as long as the parameters of foo aren't read a file.
[reply]
[d/l]
        ~/perl/monks$ cat foo.txt
sub{"fish $_[0]"};

        [download]
        ...then... 
        $foo_from_file = do "foo.txt";
foo("This is test 1\n", qr/test (.*)/, $foo_from_file);

sub foo { (my $text = $_[0]) =~ s/$_[1]/$_[2]->($1)/e;
          print $text; }

        [download]
[reply]
[d/l]
[select]
Re^2: How do I pass $1 to s///?
by Anonymous Monk on Jan 06, 2006 at 17:19 UTC
    Slightly nicer as... 
    (my $text = $_[0]) =~ s/$_[1]/$_[2]/ee;

    [download]
[reply]
[d/l]
      I call that uglier since it hides the eval. eval EXPR is something that should be glaring, blinking and alarming.
[reply]
[d/l]
[select]
Re^2: How do I pass $1 to s///?
by Anonymous Monk on Jan 06, 2006 at 17:07 UTC
    Ah, thankyou! The only problem is that I want to pass a much more complicated string in than "fish $1"... What do you mean by a templating system? Can you point me at a webpage or something? Thanks for the replies BTW! It's most appreciated! (You monks reply fast too! :)
[reply]

      You can pass any Perl source code in the above snippet (which is why it's potentially dangerous).

      One templating system would be the Template Toolkit. 

      use Template;

sub foo {
   my $template = Template->new();

   (my $text = $_[0]) =~ s/$_[1]/
      my $output = '';
      my @matches =
         map { substr($text, $-[$_], $+[$_] - $-[$_]) } 1 .. $#-;
      $template->process(\$_[2], { matches => \@matches }, \$output);
      $output
   /e;
   print $text;
}

foo("This is test 1\n", qr/test (.*)/, 'fish [% matches.1 %]');

      [download]

      (Untested)

[reply]
[d/l]
[reply]

In Section Seekers of Perl Wisdom