in reply to Parsing SOAP::Lite results

G'day Roboz,

You effectively have arrays nested within arrays, so you'll need some sort of nested loops to read the data.

If you change

foreach my $e (@{$getToysResults->{Toys}{Toy}}){
    print "$e->{ToyLocations}{ToyLocation}{locationName}\n";
}

[download]

to

foreach my $e (@{$getToysResults->{Toys}{Toy}}) {
    my $location_array_ref = $e->{ToyLocations}{ToyLocation};
    
    for my $location_array_hash_ref (@$location_array_ref) {
        print $location_array_hash_ref->{locationName}, "\n";
    } 
}

[download]

you'll get the results you're after.

[Aside: On first viewing, I found your naming conventions somewhat counter-intuitive: Toys and ToyLocations are both plural but point to single objects; Toy and ToyLocation are both singular but point to (potentially) multiple objects. In the context of the Dumper output, it's fairly easy to see what's intended; in isolation, those names may easily lead to problems of misinterpretation (particularly if you or someone else revisits the code 12 months down the track).]

-- Ken

Replies are listed 'Best First'.
Re^2: Parsing SOAP::Lite results
by Roboz (Novice) on Sep 28, 2012 at 11:14 UTC

    Tried your suggestion and received a 'Not an ARRAY reference' error on the for my $location_array_hash_ref (@$location_array_ref) { line...

    Yeah, the naming convention is due to an XML schema I have no control over.

[reply]
[d/l]

      I tested that code before posting. I changed $VAR1 to my $getToysResults but otherwise left the Dumper output unchanged. Here's the script (pm_parse_soap_hash.pl) in its entirety: 

      #!/usr/bin/env perl

use strict;
use warnings;

my $getToysResults = {
  'Toys' => bless( {
           'Toy' => [
              bless( {
               'ToyLocations' => bless( {
                               'ToyLocation' => [
                                                {
                                            'toyQuantity' => '1',
                                            'locationName' => 'toybox'
                                                },
                                                {
                                            'toyQuantity' => '4',
                                            'locationName' => 'shelf'
                                                }
                                                ]
                                 }, 'ArrayOfToyLocation' ),
               'color' => 'none',
               'toyName' => 'Sorry',
               'size' => 'medium'
               }, 'Board' )
              ]
        }, 'ArrayOfToy' )
     };

foreach my $e (@{$getToysResults->{Toys}{Toy}}) {
    my $location_array_ref = $e->{ToyLocations}{ToyLocation};
    
    for my $location_array_hash_ref (@$location_array_ref) {
        print $location_array_hash_ref->{locationName}, "\n";
    } 
}

      [download]

      Here's the output:

      $ pm_parse_soap_hash.pl
toybox
shelf

      [download]

      Try running that script. If it works, then maybe the data you posted was incorrect (typo, cut-and-paste error, etc.) or perhaps you used my code differently. Try adding print Dumper $getToysResults; just before the outer foreach in your code and see if it produces the same output as you originally posted.

      If it doesn't work, please post full output along with your Perl version and OS: as it stands, I can't see anything there that wouldn't work on any version of Perl 5.

      -- Ken

[reply]
[d/l]
[select]

        I see what's causing my issue with the 'Not an ARRAY ref' error. When there is only one location it's not an array.

        $VAR1 = {
  'Toys' => bless( {
           'Toy' => [
              bless( {
               'ToyLocations' => bless( {
                               'ToyLocation' => {
                                                'toyQuantity' => '2',
                                                'locationName' => 'toy
+box'
                                                }
                                 }, 'ArrayOfToyLocation' ),
               'color' => 'brown',
               'toyName' => 'bear',
               'size' => 'large'
               }, 'Stuffed' ),
          bless( {
               'ToyLocations' => bless( {
                               'ToyLocation' => [
                                                {
                                                'toyQuantity' => '1',
                                                'locationName' => 'toy
+box'
                                                },
                                                {
                                                'toyQuantity' => '4',
                                                'locationName' => 'she
+lf'
                                                }
                                                ]
                                 }, 'ArrayOfToyLocation' ),
               'color' => 'none',
               'toyName' => 'Sorry',
               'size' => 'medium'
               }, 'Board' )
              ]
        }, 'ArrayOfToy' )
     };

        [download]

        Still stuck on what to do in this case. Would this be where introspection comes in?  pseudo:(if HASH, then ... %$location) elsif ARRAY, then ... @$location)  ? Thanks to all who are helping me learn this!

[reply]
[d/l]
[select]
      Hi,

      Kcott's code works perfectly.
      Maybe, you are not saving the changes you made to your script.
      However, if the double for loop used confuses you, you can consider this:

      use warnings;
use strict;

my $getToysResults = {
    'Toys' => bless(
        {
            'Toy' => [
                bless(
                    {
                        'ToyLocations' => bless(
                            {
                                'ToyLocation' => [
                                    {
                                        'toyQuantity'  => '1',
                                        'locationName' => 'toybox'
                                    },
                                    {
                                        'toyQuantity'  => '4',
                                        'locationName' => 'shelf'
                                    }
                                ]
                            },
                            'ArrayOfToyLocation'
                        ),
                        'color'   => 'none',
                        'toyName' => 'Sorry',
                        'size'    => 'medium'
                    },
                    'Board'
                )
            ]
        },
        'ArrayOfToy'
    )
};

foreach my $e ( @{ $getToysResults->{Toys}{Toy} } ) {
    print join "\n" => map { $_->{locationName} }
      @{ $e->{ToyLocations}{ToyLocation} };
}

      [download]

      If you tell me, I'll forget.
      If you show me, I'll remember.
      if you involve me, I'll understand.
      --- Author unknown to me
[reply]
[d/l]

In Section Seekers of Perl Wisdom