my $now = time;
my @now = localtime $now;
my $start_of_today = $now - $now[0] - 60 * $now[1] - 3600 * $now[2];
my $days_since_monday = ($now[6]+6) % 7;
my $start_of_monday = $start_of_today - 86400 * $days_since_monday;
[download]

This fails around a DST switchover, but only by being an hour too much or too little. No biggy if you aren't publishing press releases sunday night at midnight. {grin}

-- Randal L. Schwartz, Perl hacker

I think your algorithm is a little more complex than necessary. I'd do something like this:

#!/usr/bin/perl -w

use strict;
use Time::Local;

# Get the epoch time and the day of the week
my $now = time;
my $dow = (localtime($now))[6];

# Get the various elements of the current date and time,
# subtracting the correct number of seconds to move to
# the previous Sunday.
# N.B. 86_400 is the number of seconds in a day
my @time = localtime($now - ($dow * 86_400));

# Move to the previous midnight
@time[0 .. 2] = (0, 0, 0);

# Get the epoch seconds. This is now the
# start of the previous Sunday
my $sunday = timelocal(@time[0 .. 5]);

# Add a day to get to the start of the previous
# Monday
my $monday = $sunday + 86_400;

# At this point you can do what you want with this
# number  - maybe use it in the where clause of
# a database query.
print scalar localtime $monday;
[download]

"Perl makes the fun jobs fun
and the boring jobs bearable" - me

%U     week of year, Sunday as first day of week     - 01 to 53
%W     week of year, Monday as first day of week     - 01 to 53
[download]

get today's date.
get today's week of year. (WOY)
while the current day's WOY = today's WOY
    retrieve and print articles
[download]

use POSIX;
use strict;

#
#   get epoch time and format to Week of Year.
#
my $today = time;
my $current = strftime("%W",localtime($today));




#
#   Is today a sunday?
#
if (strftime("%w",localtime ($today))==0) {
    #
    #   Yes, retrieve last week's news.
    #
    print "getting last week's news.\n";
} else {
    #
    #   Nope, look for each day this week.
    #
    my $check = $current;
    while ($check==$current) {  
        #
        #   while WOYs are equal, retrieve that day's news.
        #
        print scalar(localtime($today)) , " is this week. Retrieving a
+rticles.\n";
        #
        #   back a day.
        #
        $today -=86400;
        $check = strftime("%W",localtime($today));
    }
}
[download]

Since Sunday (or, if you like, Monday) is the beginning of the week, the "this week" asks for everything from that day to the present. So, just have some code figure out when the most recent $FirstDayOfWeek was. Date::Manip makes this easy, I bet it's easy with Date::Calc too. The former is kind of heavyweight for this task; the latter is definitely recommended for any serious mangling dates.

Just for fun, and much later than merlyn and davorg presented their (more elegant) versions, here's something from off the top of my head that uses no modules, is only barely tested, and is decidedly ugly (assumes Sunday is the date to fix on):

# returns the DD-MM-YYYY of the most recent Sunday

sub last_sunday {
    my $from = shift;
        my $time = localtime($from);
        my $day_of_week = (split /\s/, $time)[0];
        # if today is Sunday, then we just want stuff
        # since midnight
        return date_format($from) if $day_of_week eq 'Sun';
        foreach my $i (1..7) {
                my $day_of_week_then = (split /\s/,
                        localtime($from - $i * 86400))[0];
               return date_format($from - $i *86400)
                        if $day_of_week_then eq 'Sun';
        }
}

sub date_format {
        my $timestamp = shift;
        my @times = localtime $timestamp;
        return sprintf("%02d-%02d-%4d", $times[3], $times[4]+1, $times
+[5]+1900);
}
[download]

HTH

Philosophy can be made out of anything. Or less -- Jerry A. Fodor

Yeah, yeah... I knew there was a better way, I just couldn't think of it. Thanks a lot guys, especially to Randal who offered what I thought was the most elegant solution - your code is now embedded in my application and working fine... cheers.