G'day starface245,

That's not really enough information to provide a definitive answer.

Do you get that error once or multiple times? Is script.pl in the same directory as the *.msg files or accessible via $PATH? Have you tried anything to track down why the file(s) can't be found? Is the error being emitted by the code you posted or script.pl? Can you show us the code in script.pl?

You could try something like the following (redirecting the output to a temporary file and searching for No such file or directory).

$ perl -e '
use strict;
use warnings;
my @files = glob("*.msg");
for my $file (@files) {
    my $cmd = "ls -l $file";
    system($cmd);
}
'
-rw-r--r--  1 ken  staff  10 26 Oct 03:01 a.msg
-rw-r--r--  1 ken  staff  10 26 Oct 03:01 b.msg
-rw-r--r--  1 ken  staff  10 26 Oct 03:02 c.msg
[download]

With a script.pl like this:

$ cat script.pl
while (<>) {
    print "$_\n";
}
[download]

This code works fine for me:

$ perl -e '
use strict;
use warnings;
my @files = glob("*.msg");
for my $file (@files) {
    my $cmd = "perl script.pl < $file";
    system($cmd);
}
'
Message A

Message B

Message C
[download]

But I also get the same output with a single line:

$ perl script.pl *.msg
Message A

Message B

Message C
[download]

Consider whether you really need thousands of shell and Perl processes if a single Perl process would do the same job.

Your code works for me, how do I escape with filenames that has spaces and special characters? such as "A_name sub.msg"

As aitap said above, quotemeta will do that, a la my $escaped  = quotemeta($file); or even $cmd = "perl script.pl < \Q$file\E";

---

#11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.

The simplest solution from my perspective would be to avoid shelling and modify script.pl to process multiple files. That will give you access to the actual diagnostics and remove a layer of misdirection.

Update: If you can't modify script.pl for whatever reason, you can handle the file opens and piping yourself with something like:

#!/usr/bin/perl -w
use strict;

my @files = glob("*.msg");
foreach my $file(@files) {
    open my $in, '<', $file or die "Open fail on $file: $!\n";
    my @lines = <$in>;

    open my $out, '|-', 'perl script.pl' or die "Piping fail: $!\n";
    print $out @lines;
}
[download]

Do any of those .msg files have spaces in their names?

Yes it does have spaces in the name.

That's causing your problem. You are only using the chunk before the first space for each file.

I haven't had a chance to test this in your exact usage situation, but try the following. It replaces spaces in the file names with escaped spaces.

#!/usr/bin/perl
@files = glob("*.msg");
foreach $file(@files) {
    $file =~ s/ /\\\ /g;
    $cmd = "perl script.pl < $file";
    system($cmd);
}
[download]

Hi starface245,

The error message you provided leads me to believe you're on a Windows system. If that's not the case, this might not work, so feel free to disregard.

Putting the file name itself in double quotes might be the answer here.

$cmd = "perl script.pl < \"$file\""; (somewhat tested)