use warnings;
use strict;

for (glob '*.a') {
    if (-f $_) {
        print "file $_ exists\n";
    }
}
[download]

UPDATE: Fixed typo (thanks 2teez)

Much Thanks.

With that I brewed the following:

sub fexist($) {
  my $str = shift;
  for (glob qq("$str")) {
    return 1 if -e "$_";
  }
  return 0;
}
[download]

However I have use for the Link, Directory, File result so:

sub fexist($) {
  my $str = shift;
  for (glob qq("$str")) {
    return 3 if -l "$_";
    return 2 if -d "$_";
    return 1 if -f "$_";
  }
  return 0;
}
[download]

Critiques ??
Comments ??
Suggestions ??
Improvements ??

Thanks

-Enjoy
fh : )_~

Critiques ??

As a general rule, avoid subroutine prototypes unless you have good reason for them. (See, e.g., Far More than Everything You've Ever Wanted to Know about Prototypes in Perl -- by Tom Christiansen.) With the prototype removed, and employing some Perl idioms, sub fexist can be simplified to:

sub fexist
{
    for (glob $_[0])
    {
        return 3 if -l;
        return 2 if -d;
        return 1 if -f;
    }

    return 0;
}
[download]

Improvements ??

Since the aim is to cleanup unwanted files, perhaps it would be better to integrate sub fexist with the cleanup code? Something like this:

use v5.14;
...
sub cleanup
{
    for (glob $_[0])
    {
        cleanup_link($_) when -l;
        cleanup_dir ($_) when -d;
        cleanup_file($_) when -f;
    }
}
[download]

Hope that helps,

Athanasius <°(((>< contra mundum

One more small detail, which probably won't be significant unless you happen to be scanning very large quantities of files, links and/or directories: you can use the special operand "_" (the underscore character) on the file-test operators, in order to use the file stat information from the previous stat call (so you don't do repeated stat calls on the same file). Adapting the most recent suggestion from Athanasius:

sub cleanup
{
    for (glob $_[0])
    {
        cleanup_link($_) when -l;
        cleanup_dir ($_) when -d _;
        cleanup_file($_) when -f _;
    }
}
[download]

I think to do this successfully you will have to use opendir with the path and then use readdir to put the contents in an array. Then loop through the array testing with -f. Check 'perldoc -f opendir'. You will have to add the path back in front of the filename when doing filename check.

Nevermind. I misunderstood what you were trying to do.

I have chosen to stick with the simple fexist sub:

sub fexist {
my $str = shift;                     # newMeth REMOVE!
#  for (glob qq("$_[0]")) {          # newMeth CHANGE!
  for (glob qq("$str")) {
    return 3 if -l;
    return 2 if -d _;
    return 1 if -f _;
  }
  return 0;
}
[download]

The quoting is the result of hacking to get it to work with spacy names.
I believe it still fails on spacy wildcard names, got real sick and had to put it all aside for now and take care of myself.

Current script, reads a file list of file/directory names and deletes them, Everything after a : and blank lines are ignored.

#!/usr/bin/perl

# fh :)_~
# do with as you wish ...
# Just don't blame me if it teaches your computer to smoke!

use strict;
use warnings;

use File::Basename;

my $Prog   = "cmake -E";
my $RmDir  = "remove_directory";
my $RmFile = "remove -f";
my $Cmd;

sub fexist {
my $str = shift;                     # newMeth REMOVE!
#  for (glob qq("$_[0]")) {          # newMeth ADD!
  for (glob qq("$str")) {
    return 3 if -l;
    return 2 if -d _;
    return 1 if -f _;
  }
  return 0;
}

sub main {

  my $dir = dirname(__FILE__);

  open(FILE, "$dir/clean.list") or die("Unable to open file: $dir/clea
+n.list.");
  my @data = <FILE>;
  close(FILE);

  foreach my $line (@data) {

    next if $line =~ /^$/;  # skip blank lines
    next if $line =~ /:/;   # skip lines with a ':' (colon) in them
    chomp $line;

    next if not my $rval = fexist $line;

    $Cmd = join " ", $Prog, ($rval eq 2) ? $RmDir : $RmFile;

    print "Deleting $line";
    system("$Cmd \"$line\"");
    print " ... Deleted!" unless fexist $line;
    print "\n";
  }
}

main();
[download]

Example clean.list

: Everything after a : and blank lines are ignored
:

install_manifest.txt
cmake_install.cmake
cmake_uninstall.cmake
CMakeCache.txt
Makefile
CMakeFiles
[download]

Thanks

-Enjoy
fh : )_~

Ok, Took the advice and made a few changes ... :)

I could not get the "when" usage to work!
Running at least Perl v5.16.0
Tried as described in perlsys

So the latest version.

#!/usr/bin/perl

use strict;
use warnings;

#  **
#  * BCE 42.
#  * Read a list of file names from a file and delete them.
#  **
#
#  **
#  * It is what it is, you can do with it as you please. [with respect
+, leave the credits]
#  *
#  * Just don't blame me if it teaches your computer to smoke!
#  *
#  *  -Enjoy
#  *  fh :)_~
#  **
#
#  ** Example clean.list
#  * : Everything after a : and blank lines are ignored
#  * : Wildcards are valid, be careful.
#  * :
#  *
#  * install_manifest.txt
#  * cmake_install.cmake
#  * CMakeCache*
#  * examples/*.a
#  **

use File::Basename;

my $Prog   = "cmake -E";
my $RmDir  = "remove_directory";
my $RmFile = "remove -f";
my $RmLink = "remove -f";

sub runCommand
{
    return `$Prog $_[0] \"$_[1]\"` if $_[0] && $_[1];
    return -1;
}

sub cleanup_Link    # non Win32
{
    print "Deleting Link: $_[0]";
    runCommand($RmLink, $_[0]);
    print " ... Deleted!" if not -l $_[0];
    print "\n";
}

sub cleanup_Dir
{
    print "Deleting Dir : $_[0]";
    runCommand($RmDir, $_[0]);
    print " ... Deleted!" if not -d $_[0];
    print "\n";
}

sub cleanup_File
{
    print "Deleting File: $_[0]";
    runCommand($RmFile, $_[0]);
    print " ... Deleted!" if not -f $_[0];
    print "\n";
}

sub cleanup
{
    for (glob qq("$_[0]")) {
        cleanup_Link($_) if -l;        # non Win32
        cleanup_Dir ($_) if -d _;
        cleanup_File($_) if -f _;
    }
}

sub main
{
    my $Dir = dirname(__FILE__);

    open(FILE, "$Dir/clean.list") or die("Unable to open file: $Dir/cl
+ean.list.");
    my @Data = <FILE>;
    close(FILE);

    foreach my $line (@Data) {
        next if $line =~ /^$/;  # skip blank lines
        next if $line =~ /:/;   # skip comment lines with ':' (colon) 
+in them
        chomp $line;        # trim the newline
        cleanup($line);
    }
}

main();
[download]

Critiques ??
Comments ??
Suggestions ??
Improvements ??

Thanks

-Enjoy
fh : )_~