Your statement:

 if ( $currentFile eq $searchfile )
[download]

It is unlikely to find a file with that name.
You could use regular expressions to match the file name, but I would recommend re-designing your code around the File::Find module and friends (File::Find::Match).

The error is as NetWallah says, that you are checking to see if the filename equals "abc*.xml*" - not if the filename matches that pattern.

Personally I'd use Path::Class::Rule...

# untested!
use strict;
use warnings;
use Path::Class::Rule;

my $rule = Path::Class::Rule->new->file->name("abc*.xml*");

$_->remove for $rule->all("/tst");
[download]

qwerty80:

You already have several good answers, so I'm not really adding much. However, I've not played much with opendir or readdir and I thought I'd like to play with them a bit. I didn't want a recursive solution, so I did it this way:

$ cat 1004138.pl 
#!/usr/bin/perl
use strict;
use warnings;
use 5.10.0;
use autodie;

my $filespec = "abc*.xml";
my @dirs = ('ABC');

while (@dirs) {
    my $curdir = pop @dirs;
    opendir(my $dh, $curdir);
    for my $f (readdir($dh)) {
        next if $f =~ /^\.\.?$/;
        next unless -d "$curdir/$f";
        print "pushing $curdir/$f\n";
        push @dirs, "$curdir/$f";
    }

    for (glob("$curdir/$filespec")) {
        print "processing $_\n";
    }
}

$ perl 1004138.pl
pushing ABC/DEF
pushing ABC/GHI
pushing ABC/JKL
processing ABC/abcde.xml
processing ABC/JKL/abc_x.xml
processing ABC/JKL/abc_y.xml
processing ABC/JKL/abc_z.xml
pushing ABC/GHI/baz
pushing ABC/GHI/foo
pushing ABC/GHI/bar
processing ABC/GHI/abc_5.xml
processing ABC/GHI/abc_6.xml
processing ABC/GHI/bar/abc_1.xml
processing ABC/GHI/bar/abc_2.xml
processing ABC/GHI/bar/abc_3.xml
processing ABC/GHI/bar/abc_4.xml
processing ABC/GHI/foo/abc_8.xml
processing ABC/GHI/foo/abc_9.xml
processing ABC/GHI/foo/abc_a.xml
processing ABC/GHI/foo/abc_b.xml
processing ABC/GHI/baz/abc_{7}.xml
[download]

It's not particularly pretty, but it amused me for a few minutes. I didn't actually let it do file deletions because I'm loath to do automatic deletes until I've well tested such a script. It's a good thing, too. On my earlier attempt, a pair of bugs conspired to make the script "process" all "abc*.xml" files on my hard drive, rather than just those in the ABC directory.

...roboticus

When your only tool is a hammer, all problems look like your thumb.

"I didn't actually let it do file deletions because I'm loath to do automatic deletes until I've well tested such a script."

One nifty trick I sometimes use in situations like that is to make my script output text like this to STDOUT:

rm ABC/JKL/abc_x.xml
rm ABC/JKL/abc_y.xml
rm ABC/JKL/abc_z.xml
[download]

Then when I've played with it a few times, and I'm confident it's outputting the right commands, pipe the output into sh:

perl myscript.pl | sh
[download]

This is also good if you need to do a bunch of complex database changes. Just write SQL to STDOUT, and once you're sure it's OK, pipe it into your favourite command-line SQL tool.

perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'

find -name 'abc*xml' | xargs rm
[download]

#!/usr/bin/perl
# delete all of the *.xml* files recursively 
use File::Find qw(find);

@ARGV = qw(.) unless @ARGV;

find sub {
 return unless -f;
 return unless $_ =~ /(.*).xml(.*)/;

 unlink $_ and warn "deleted $_\n";

}, @ARGV;

# it would be good to show all dirs to be deleted
# and promp user for 'yes'

__END__
[download]

Untested:

use File::Util;

unlink for grep { $_ =~ /xml$/i }
File::Util->new->list_dir('/your/directory', '--recurse');
[download]

Or alternately:

use File::Util;

$f = File::Util->new();

unlink for grep { $_ =~ /xml$/i } $f->list_dir('/your/directory', '--r
+ecurse');
[download]