in reply to merging anonymous arrays

Your existing code is but one layer of indirection away from wielding anonymous arrays:

my $a_ref = [ qw/ A B C D E F G H / ];
my $b_ref = [ qw/ 7 6 5 4 3 2 1 0 / ];

my @KEY = map { $a_ref->[$_], $b_ref->[$_] } 0 .. $#{$a_ref};

[download]

Similar functionality also exists in List::MoreUtils with the "zip" and "mesh" functions (they're synonymous).

use List::MoreUtils qw( zip );

my $a_ref = [ qw/ A B C D E F G H / ];
my $b_ref = [ qw/ 7 6 5 4 3 2 1 0 / ];

my @KEY = zip @{$a_ref}, @{$b_ref};

[download]

Dave

Replies are listed 'Best First'.
Re^2: merging anonymous arrays
by choroba (Cardinal) on Nov 16, 2012 at 08:37 UTC
    Or, if 'anonymous' means 'not using a name nor reference', you can change it to 
    my @key = map { [qw/A B C D E F G H/]->[$_],
                [qw/7 6 5 4 3 2 1 0/]->[$_]
              } 0 .. 7;

    [download]
    In such a case, you have to specify the size externally, though, since there is no way how to refer to the arrays.
    لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ
[reply]
[d/l]
      since there is no way how to refer to the arrays

      There is if you make them arguments to an on-the-fly subroutine.

      $ perl -E '
> @key = sub {
>     map { $_[ 0 ]->[ $_ ], $_[ 1 ]->[ $_ ] }
>     0 .. $#{ $_[ 0 ] }
>     }->( [ qw{ A B C } ], [ qw{ 1 2 3 } ] );
> say qq{@key};'
A 1 B 2 C 3
$

      [download]

      A little less esoteric than ColonelPanic's clever solution ++.

      Cheers,

      JohnGG

[reply]
[d/l]

        I like the added layer of anonymity that an anonymous subroutine gives! Your mind can be at ease knowing that no one will ever be able to identify any part of your code by name.

        And then there is this, which should not have happened, but did:

        use Modern::Perl;

sub AUTOLOAD {
    our $AUTOLOAD;
    state %stuff;
    return @_ unless $AUTOLOAD=~/scalar/;
    return $stuff{$AUTOLOAD}++ ? eval $AUTOLOAD.'recursed(@_[1..$#_])'
+ : $_[0];
}

my @key = map { 
        autosub_scalariffic_list('A','B','C'),
        $_
    } autosub_list(1,2,3);

say qq{@key};

        [download]


        When's the last time you used duct tape on a duct? --Larry Wall
[reply]
[d/l]
      There is always a way :) 
      my @key = map { 
    [qw/A B C D E F G H/]->[$_],
    [qw/7 6 5 4 3 2 1 0/]->[$_]
} 0..open(F,$0)&&($_=join('',<F>))&&/map\s*{\s*(\[.*?\])/s&&
     eval"\$#{$1}";
              
print "@key";

die "Not recommended for production code!!";

      [download]


      When's the last time you used duct tape on a duct? --Larry Wall
[reply]
[d/l]
Re^2: merging anonymous arrays
by SavannahLion (Pilgrim) on Nov 16, 2012 at 08:36 UTC

    Ah Ha!
    Thank you! And now I can get rid of a and b entirely by going just one step further. I knew I was overlooking something.

    Kudos.

[reply]

In Section Seekers of Perl Wisdom