Since you understand the shift and logical or ||, then maybe a simple example will illustrate the usage:

use warnings;
use strict;

my $age = 15;

print get_age($age); #  my age is: 15
print "\n";
print get_age();     #  my age is: 200

sub get_age {
    my $my_age = shift || 200;
    return " my age is: ", $my_age;
}
[download]

Consider the following:

use strict;
use warnings;

printSomething('Hello, world.');

printSomething();

sub printSomething {
    my $string = shift || 'Nothing was sent.';
    print $string, "\n";
}
[download]

First output:

Hello, world.
[download]

Second output:

Nothing was sent.
[download]

In subroutines, shift takes the first element off @_. In the case above, $string is initialized with whatever is sent to the subroutine. However, if nothing is sent, $string is initialized with 'Nothing was sent.' This is because of the logical or operation in Perl. If the first disjunct (shift) evaluates to true, then Perl stops there, since the overall express is true. However if the first disjunct evaluates to false (nothing to shift), Perl moves to the second disjunct. Thus, printSomething() prints Nothing was sent. Here's another way to 'say' this: the variable $string equals either what was sent to the subroutine or the string 'Nothing was sent.'

Good replies so far, so I won't steal anyone's monastic thunder, although I'll add that Perls >= 5.10 have the logical defined-or operator, //. Often this is what you really want, but since there is a lot of code in the wild that pre-dates it, you may notice disproportionate use of ||.

The difference is simple:

1. Use $a //= 'foo'; when you want to assign 'foo' to $a if $a is not defined.
2. Use $a ||= 'foo'; when you want to assign 'foo' to $a if $a has a false value, such as zero or an empty string.

my $val ||= "undefined"

Which is equivalent to:

if (!$val) {
    $val = "undefined";
}
[download]

Blocks of code like that tend to clutter up your code.

Also consider:

$val = ($val) ? "defined" : "undefined";
[download]

Which is equivalent to:

if ($val) {
    $val = "defined";
}
else {
    $val = "undefined";
}
[download]

Also, remember perl evaluates expressions for truth.

Defined, undefined or false?

use strict;
use warnings;

my $val = 0;

print +($val) ? "defined" : "undefined"; # prints undefined

print "\n";

print +(defined $val) ? "defined" : "undefined"; # prints defined

undef $val;

print "\n";

print +(defined $val) ? "defined" : "undefined"; # prints undefined
[download]

Do you understand Perl's logical ||? The key point in the context you are having trouble understanding is that the tested value is returned. Other languages with a logical or return a boolean value. Perl returns the actual value. So:

0 || 'wibble'
[download]

returns the string wibble, not 1, -1 or true as you might get in other languages. That makes logical or very useful for providing default values.