print {$self->{tempfile}} "I am here";
[download]

Otherwise, the interpreter doesn't realize that is a filehandle.

Some, though not all, monks consider it a good practice to always use braces for filehandle references.

The two answers above should address the problem you're having. Here are some style tips though...

In these two lines, you are treating $self like it is a hashref...

$self->{tempfile} = File::Temp->new(UNLINK => 1, SUFFIX => '.tmp');
print $self->{tempfile} "I am here";
[download]

But self is not a hashref; it's an object. OK, so Moose implements objects as blessed hashrefs by default, but it is considered bad form to treat an object as a hashref - we're supposed to pretend that it's not a hashref, and only access the internals via the accessors that Moose gives us. So we should do this...

$self->tempfile( File::Temp->new(UNLINK => 1, SUFFIX => '.tmp') );
print {$self->tempfile} "I am here";
[download]

The reasons for doing so are not just theoretical. Accessing the object as a hashref bypasses all your type constraints, triggers, etc.

Secondly, you are initialising an attribute within the BUILD method. While you can do that, Moose does provide attribute defaults and builders for this sort of thing:

package test;   # not 'test.pm'
use Moose;
use File::Temp;

has tempfile => (
    is       => 'rw',
    isa      => 'File::Temp',
    lazy     => 1,
    default  => sub {
        File::Temp->new(UNLINK => 1, SUFFIX => '.tmp')
    },
);

sub BUILD {
    my $self = shift;
    print { $self->tempfile } "I am here";
}
[download]

hi gsiglet,

Just as ColonelPanic, mentioned previously,

The following from print, in Perl Documentation could shield more light:

If you're storing handles in an array or hash, or in general whenever you're using any expression more complex than a bareword handle or a plain, unsubscripted scalar variable to retrieve it, you will have to use a block returning the filehandle value instead, in which case the LIST may not be omitted:
print { $files[$i] } "stuff\n";

package test;

use Moose;
use FileHandle;

has 'fh' => (
   is => 'rw',
   isa => 'FileHandle',
   lazy => 1,
   default => sub { FileHandle->new },
);

sub BUILD {
   my $self = shift;

   open $self->{fh} , "<", "temp.txt";
   while (<$self->{fh}>) {
      print $_;
   }
}
[download]

Syntax error at test.pm line 17, near "<$self->{fh"
[download]

You may have some difficulty with isa => 'FileHandle' because while FileHandle is a core Perl module, Moose uses the type constraint string "FileHandle" to refer to unblessed Perl file handles - i.e. not objects created by the FileHandle package.

open my $fh , "<", "temp.txt";
$self->fh($fh);
while (<$fh>) {
  print $_;
}
[download]

perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'

So it is impossible to use  while(<$self->{IamAfileHandleAttribute}>) { ... } > to read a file, outside my constructor. I guess I will have to do:

my $temp_fh = $self->{IamAfileHandleAttribute};
while (<$temp_fh>) {
   ...
}
[download]