use Modern::Perl;

my @test = (
    "text text text 1 text",
    "1 text text text 2 text 3",
    "text 1 text text 2 text",
    "text text text 1 text 2 3.0",
    "1 2 3 4 5 6 7 8 9 10 11",
    "text text 4.5 text text"
);

for (@test) {
    say "$_: $1" if /(\d+)\.?\d*?\D*?$/;
}
[download]

text text text 1 text: 1
1 text text text 2 text 3: 3
text 1 text text 2 text: 2
text text text 1 text 2 3.0: 3
1 2 3 4 5 6 7 8 9 10 11: 11
text text 4.5 text text: 4
[download]

If you really want the last integer in a string, you can find that as /.*(?<!\d)(\d+)/, and get the numbers as

my @filtered = map { /.*(?<!\d)(\d+)/; $1 // '' } @lines;
[download]

However you seem to want to turn 3.0 into 3 (and not 0), and I don't know the rules behind that. Do you want to permit decimals, and cut off zero-decimals behind the dot? Or something else?

>perl -wMstrict -le
"my @lines = ('xx',  '0 xx',  '1 xx 3.2');
 ;;
 'Zonk' =~ m{ (\w+) }xms;
 ;;
 my @filtered = map { /.*(?<!\d)(\d+)/; $1 // '' } @lines;
 printf qq{'$_' } for @filtered;
"
'Zonk' '0' '2'
[download]

Right, I forget about Perl 5's insane behavior about capture variables when a match failed. The correct way would be to use /.../ and $1 // '' or some variation thereof.

Perl 6 - the future is here, just unevenly distributed

Thanks for the feedback! The numbers are actually section numbers so sometimes they are written "section 1" and sometimes it could be "section 1.", "section 1)", "section 1.)", etc.

So what's the extraction rule? One can make a guess based on the examples just given, but an explicit definition is always nice to have.

Yet another approach (founded, in part, on moritz' point that the rule for dealing with decimals is UNspecified).

Given the OP, if the the spec is that trailing decimal digits should be truncated to integers (let us hope there's no hidden requirement for rounding :) ) then a two-part approach is also viable.

So, less elegantly but, IMO, very obvious in its tactics and using regular expressions similar to those proposed above, a TIMTOWTDI might look like this:

#!/usr/bin/perl
use 5.014;

#1004756

my @init_array = ("text text text 1 text",
                "1 text text text 2 text 3 ",
                "text 1 text text 2 text",
                "text text text 1 text 2 3.0",
                "1 2 3 4 5 6 7 8 9 10 11",
                "text text text text",
                );

my ($sub_select, $select, @selected);

for $_(@init_array) {
    $_ =~ s/(.+)\.0\z/$1/;      # Truncate trailing decimal numbers
    say "\t \$_: $_";           # debug

    ($select) = $_ =~ /
                .+?
                (?:(\d+))
                (?:[\D]*)
                $               # EOL
                /x;
    push @selected, $select;
}

my $i = 0;
for my $captured(@selected) {
    say "\t\t" . '#test_filtered' . "[$i]: " . '"' . $captured . '"';
    $i++;
}

=head EXECUTION:

C:\>perl 1004756.pl
         $_: text text text 1 text
         $_: 1 text text text 2 text 3
         $_: text 1 text text 2 text
         $_: text text text 1 text 2 3
         $_: 1 2 3 4 5 6 7 8 9 10 11
         $_: text text text text
                #test_filtered[0]: "1"
                #test_filtered[1]: "3"
                #test_filtered[2]: "2"
                #test_filtered[3]: "3"
                #test_filtered[4]: "11"
                #test_filtered[5]: ""

=cut
[download]

Update: added intermediate variables.

my @test = (
    "text text text 1 text",
    "1 text text text 2 text 3 ",
    "text 1 text text 2 text",
    "text text text 1 text 2 3.0",
    "1 2 3 4 5 6 7 8 9 10 11",
    "text text text text"
);

my @filtered = map {/(\d+)(?:\.0*)?\D*$/; $1} @test;

print join "\n", @filtered;
[download]

1
3
2
3
11

Or possibly, depending on your needs, something like:

my @filtered = map {/(\d+(?:\.\d*)?)\D*$/; 0 + $1 || ''} @test;

print join "\n", @filtered;
[download]

The solutions you propose have various problems:

• handling a number like 3.0, of which daugh016 seems to want to capture only the integer portion;
• handling 0;
• and the problem of having capture variables undefined if a match fails (or else having the value of these variables persist from a previous match).

Here is a possible solution avoiding those problems:

>perl -wMstrict -le
"my @test = (
   'text text text 1 text',
   '1 text text text 2 text 3 ',
   'text 1 text text 2 text',
   'text text text 1 text 2 3.0',
   '1 2 3 4 5 6 7 8 9 10 11',
   'text 0',  'text 3.1',
   'text text text text',
   );
 ;;
 'Zonk' =~ m{ (\w+) }xms;
 ;;
 my @filtered = map {/(\d+)(?:\.0*)?\D*$/; $1} @test;
 printf qq{'$_' } for @filtered;
 print qq{\n};
 ;;
 @filtered = map {/(\d+(?:\.\d*)?)\D*$/; 0 + $1 || ''} @test;
 printf qq{'$_' } for @filtered;
 print qq{\n};
 ;;
 @filtered =
   map { m{ (\d+) (?: [.] \d*)? \D* \z }xms ? $1 : '' }
   @test
   ;
 printf qq{'$_' } for @filtered;
 print qq{\n};
"
'1' '3' '2' '3' '11' '0' '1' 'Zonk'

Argument "Zonk" isn't numeric in addition (+) at -e line 1.
'1' '3' '2' '3' '11' '' '3.1' ''

'1' '3' '2' '3' '11' '0' '3' ''
[download]

Here's another option:

my @test_filtered = map { (/(\d+)[\d.]*/g)[-1] // ''  } @test;
[download]

Update: changed to // to handle 0s. Thanks again, AnomalousMonk.

>perl -wMstrict -le
"my @test = ('0 xx',  'xx 0',  '0');
 ;;
 my @test_filtered = map { (/(\d+)[\d.]*/g)[-1] || '' } @test;
 printf qq{'$_' } for @test_filtered;
"
'' '' ''
[download]

Update:  // vice  || does the trick.

Excellent catch, thank you! Changed disjunct positions...