"..$results[$loopcount] [1] = (@$row[1]); THIS LINE IS NOT WORKING..."

If I get your question right, and you suppose to generate an ARRAY of ARRAY, you could do something like this: Please note, this will only show you how to go about solving your question

my @AoA;

while (<DATA>) {
    push @AoA, [split];
}

use Data::Dump;
dd \@AoA;

__DATA__
First line of the file.
Second line of the file.
Third line of the file.
Fourth line of the file.
Fifth line of the file.
Sixth line of the file.
[download]

[
  ["First", "line", "of", "the", "file."],
  ["Second", "line", "of", "the", "file."],
  ["Third", "line", "of", "the", "file."],
  ["Fourth", "line", "of", "the", "file."],
  ["Fifth", "line", "of", "the", "file."],
  ["Sixth", "line", "of", "the", "file."],
]
[download]

Here is sample code:

my @allrows = @{ $sth->fetchrow_arrayref() }; # Expand ref, to simplif
+y access

my $first_author        = $allrows[0][0]; 
my $second_author       = $allrows[1][0];
my $first_title         = $allrows[0][1];
[download]

$language   = $row[2];   # Correct
$language   = @$row[2];  # wrong (at least in perl ver 5)
[download]

A little known "feature" of fetchall_arrayref is that it will return an array of hashes if you supply it a hash, and if that hash is empty, it will return all the fields.

my @allrows = @{ $sth->fetchrow_arrayref({}) }; # Expand ref, to simpl
+ify access
[download]

YMMV, but I always find it easier to look at $row{language} than $row[2]. I'm sure there's a mild performance hit, but as long as it's not incredibly slow I'd opt for clarity.

A Monk aims to give answers to those who have none, and to learn from those who know more.

Ah - learned something today - thank you.

I avoid "fetchall_*", because I mostly process a row-at-a-time , and use the clearer syntax of fetchrow_hashref.

The OP's questions were based on managing arrays, and I did not want to bring hashes and confuse that discussion.

Thanks, space_monk.

             "By three methods we may learn wisdom: First, by reflection, which is noblest; Second, by imitation, which is easiest; and third by experience, which is the bitterest."           -Confucius

I didn't really understand the context but for the following line

$results[$loopcount] [1] = (@$row[1]); THIS LINE IS NOT WORKING.

can't work, since you can't assign an @array-list to an array element¹, only scalars (simple or references)

in your case you have the option between

$results[$loopcount][1] = $row[1]

which copies references

or

$results[$loopcount][1] = [@$row[1]]

which creates a new array-reference with elements copied (one-level deep)

While ignoring the rest of your post I hope this helps! =)

¹) well you won't get an error here, because Perl will take the size of the array in scalar context.

The little program I wrote returns all rows as an array of hashes. The text after the __END__ token shows a select * from the command line, (to show the contents of the id_minutes table).

The text after the sqlite result is the Data::Dumper output of the array of hashes.

#!/usr/bin/perl
use strict;
use warnings;
use DBI;
use Data::Dumper;

# t33.pl

my $dbh = DBI->connect("dbi:SQLite:dbname=junk.lite","","",
    {PrintError => 1}) or die "Can't connect";

my $query = q{SELECT * FROM id_minutes};
my $aref = $dbh->selectall_arrayref($query, { Slice => {} });
$dbh->disconnect or die $dbh->errstr;

print Dumper $aref;



__END__

C:\Old_Data\perlp>sqlite3 junk.lite
SQLite version 3.7.3
Enter ".help" for instructions
Enter SQL statements terminated with a ";"
sqlite> .mode column
sqlite> .width 10 10 10
sqlite> .head on
sqlite> select * from id_minutes;
id          month       minutes
----------  ----------  ----------
maclaw796   Oct         6
hturner     Oct         53
nnt         Oct         3
sqlite>


C:\Old_Data\perlp>perl t33.pl
$VAR1 = [
          {
            'month' => 'Oct',
            'minutes' => 6,
            'id' => 'maclaw796'
          },
          {
            'month' => 'Oct',
            'minutes' => 53,
            'id' => 'hturner'
          },
          {
            'month' => 'Oct',
            'minutes' => 3,
            'id' => 'nnt'
          }
        ];

C:\Old_Data\perlp>
[download]

use strict;
use warnings;
use 5.012;

my $row1_ref = ['a', 'b', 'c'];
my $row2_ref = ['xx', 'yy', 'zz'];

my $data; 
push @$data, $row1_ref;
push @$data, $row2_ref;


use Data::Dumper;
say Dumper($data);

--output:--
$VAR1 = [
          [
            'a',
            'b',
            'c'
          ],
          [
            'xx',
            'yy',
            'zz'
          ]
        ];
[download]

my( $author, $title, $results ) ;

while ( my($lineno, $row_ref) = each @$data) {
    $author = $row_ref->[0];
    $title = $row_ref->[1];
    $results->[$lineno]->[1] = $row_ref->[2];
}

say Dumper($results);


--output:--
$VAR1 = [
          [
            undef,
            'c'
          ],
          [
            undef,
            'zz'
          ]
        ];
[download]