Maybe you want a templating system instead? sprintf is the simplest one, and it could be used in your case as follows:

$foo = "hello";
my $x = "$foo%s";
my $output = sprintf $x, $y; # replaces "%s" with $y
print $output;
[download]

There are many, many more templating systems, with varying easy of use and complexity. I recommend looking at simple string substitution first.

Hello rbala,

I'm guessing, but is this what you want to do?

perl -e '$x="hello "; while( $y=glob("*") ) { print "$x$y\n"; }'
[download]

If you had 'use strict' in your code, you would have gotten an error on your second line. I'm using 'glob', but any source of input and assignment of '$y' will work.

When using Perl, you should think of how to do it with Perl. Your experience with 'makefile' is nice, but has nothing to do with what is correct in Perl!

Good Luck!

This is about the closest I could get...

use strict;
use warnings;

BEGIN {
    package JIT;  # Just In Time evaluation
    $INC{'JIT.pm'} = __FILE__;
    
    use base 'Exporter';
    our @EXPORT = 'jit';
    sub jit (&) { bless $_[0] }
    
    use overload
        q[""]    => 'evaluate',
        q[0+]    => 'evaluate',
        q[bool]  => 'evaluate',
        fallback => 1;
    sub evaluate { $_[0]->() }    
};

use JIT;

my $foo = "hello";
my $y;  # needs to be declared, but we haven't assigned a value to it 
+yet.
my $x = jit { "$foo".$y }; # $y is not yet defined.
$y = "world";              # now define $y
print $x;
[download]

You could do it with anonymous subroutines. Just assume that every variable is a subroutine. It's not very pretty, though.

my %vars; # something to hold all your variables in

sub set_var {
    my ($name, $value) = @_;

    $vars{$name} = $value;
}

sub get_var {
    my $name = shift;
    my $var = $vars{$name};
    return ref $var eq 'CODE' ? $var->() : $var;
}

set_var(foo => "hello");
set_var(x => sub { return get_var('foo') . get_var('y') });
set_var(y => 'world');

print get_var('x'), "\n";
[download]