sandeepda:

Parsing the strings ought to be easy. It prefaces the interesting data with a bar of hyphens, and the name, IP and port ought not have whitespace. So you can simply read and discard lines until you find the line of hyphens. After that, you can use a simple split to break out the individual fields:

while (my $line = <$FH>) {
    next if $line =~ /^-----/;
    my ($name, $ip, $port) = split /\s+/, $line;
    print "Name: $name, IP: $ip, Port: $port\n";
}
[download]

Other alternatives include using substr or unpack for breaking up lines with fixed-length fields.

...roboticus

When your only tool is a hammer, all problems look like your thumb.

Hello sandeepda, and welcome to the Monastery!

If I’ve understood your question correctly, the following script should give you an idea of how to proceed:

#! perl
use Modern::Perl;

my %ports;

while (<DATA>)
{
    next unless /^http/;
    my @records = split /\s+/;

    if (exists $ports{$records[2]})
    {
        warn "Attempt to give port $records[2] a second name";
    }
    else
    {
        $ports{$records[2]} = $records[0];
    }
}

say join(' and ', get_listener_name($_)) for 6712, 4516;

sub get_listener_name
{
    my ($port_to_be_checked) = @_;
    my  @results = ('FALSE', 'a1=null');

    if (exists $ports{$port_to_be_checked})
    {
        @results = ('TRUE', 'a1=' . $ports{$port_to_be_checked} . '(li
+stener name)');
    }

    return @results;
}

__DATA__
name ip port 
------------------------------------ 
http-listener-1 * 6712 
http-listener-2 * 8709
[download]

Output:

21:40 >perl 486_SoPW.pl
TRUE and a1=http-listener-1(listener name)
FALSE and a1=null

21:40 >
[download]

Hope that helps,

Thanks Athanasius; I am trying it to make generic I am getting this output as array @outputarray also output is synamic the name and post can change How can i parse this where outputarray[0]=name ip port outputarray[0]=------------------------------------ outputarray[0]=http-listener-1 * 6712

 
name          ip   port 
------------------------------------ 
http-listener-1 * 6712 
http-listener-2 * 8709
[download]

Hello again sandeepda,

I’m sorry, but I don’t understand what you are asking.

The only thought that comes to mind is that you may be unfamiliar with Perl’s special DATA filehandle. But I used that only for convenience. If you already have the data in an array, you would adapt the opening of my script as follows:

for (@existing_array)
{
[download]

On the other hand, if the data is in a file (named, say, “ports.dat”), then you would begin like this:

my $file = 'ports.dat';
open(my $fh, '<', $file) or die "Cannot open '$file' for reading: $!";

while (<$fh>)
{
[download]

If this doesn’t answer your question, please explain what you are asking with your version of the code together with sample input and the output you want. See How do I post a question effectively?

Hope that helps,

Athanasius <°(((>< contra mundum

Iustus alius egestas vitae, eros Piratica,