#!/usr/bin/perl
use warnings;
use strict;

use Test::More;

my @checks = (
    sub {
        my ($entity, @array) = @_;
        $entity ~~ @array;
    },

    sub {
        my ($entity, @array) = @_;
        grep $entity eq $_, @array;
    },

    sub {
        my ($entity, @array) = @_;
        for (@array) {
            return 1 if $entity eq $_;
        }
        return;
    },
);

for my $check (@checks) {
    ok     $check->('b', qw(a b c));
    ok not $check->('z', qw(a b c));
}

done_testing();
[download]

You forgot to mention hashes! =)

  DB<101> sub in { 
           my ($entity, @array) = @_;
           my %hash;
           @hash{@array}=();
           return exists $hash{$entity};
           }

  DB<102> in(5,0..10)
 => 1

  DB<103> in(42,0..10)
 => ""
[download]

but I wouldn't pass @array as a flat list.

Cheers Rolf

Try

$entityName ~~ @array_to_be_checked
[download]

Update

  DB<104> @array= qw/http-listener-1 http-listener-2 http-listener-3 h
+ttp-listener-4/

  DB<106> 'http-listener-2' ~~ @array
 => 1

  DB<108> 'nonsense' ~~ @array
 => ""
[download]

check if an element exists in array

I used one of my project this way!

if ( grep( /^$value$/, @array ) ) {
  print "found it";
}
[download]

Works nicely until $value = "http+listener+1".

Make sure you \Q...\E or quotemeta your value.

perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'

++ tobyink

Thanks for the info!

You might want to change /^$value$/ to /^\Q$value\E$/, especially if $value may contain re metacharacters, but it depends on the application.

while (<>) {
    chomp;
    print qr(^$_$), "\t", qr(^\Q$_\E$), "\n";
}
__END__
foo
(?-xism:^foo$)  (?-xism:^foo$)
foo[bar]
(?-xism:^foo[bar]$)     (?-xism:^foo\[bar\]$)
[download]

--MidLifeXis

What they already said except that since you're not actually using regex, you shouldn't use regex. This will be faster and have fewer caveats (I inverted the statement as a matter of stylistic preference, not because it's necessary)–

print "Found it.\n" if grep { $_ eq $value } @array;