It works fine for me on GNU/Linux:

package Frame;

use strict;
use warnings;

use Wx qw[:everything];
use base qw(Wx::Frame);

sub new {
    my $self = shift;

    $self = $self->SUPER::new(
        undef,
        -1,
        'Test app',
        [-1, -1],
        [-1, -1],
        wxDEFAULT_FRAME_STYLE,
    );

    #- Grid Sizer
    my $sizer = Wx::GridSizer->new(2, 1);

    my $text = Wx::TextCtrl->new(
        $self, -1, q{Hello},
        [ -1, -1 ],
        [ -1, 40 ],
        wxTE_MULTILINE,
    );
    my $button = Wx::Button->new( $self, -1, '&Color',[ 70, 30 ] );

    my $hbox = Wx::BoxSizer->new(wxHORIZONTAL);

    Wx::Event::EVT_BUTTON(
        $self, $button,
        sub {
            $text->SetForegroundColour( Wx::Colour->new(255,0,0) );
            $text->SetBackgroundColour( Wx::Colour->new('yellow') );
        }
    );

    $sizer->Add( $text, 0, wxALIGN_CENTRE | wxGROW | wxALL, 2, );
    $sizer->Add( $button, 0, wxALIGN_CENTRE | wxGROW | wxALL, 2, );
    $self->SetSizer( $sizer );
    $sizer->Fit($self);

    return $self;
}

1;

package App;

use strict;
use warnings;
use base 'Wx::App';

sub OnInit {
    my $frame = Frame->new();
    $frame->Show( 1 );
}

package main;

use strict;
use warnings;

my $app = App->new();
$app->MainLoop;
[download]

Regards, Stefan

thanks.. that is good to know.. more research.. the test system is fedora 12 32bit. some of the target systems are older unfortunately.

From:

wxWidgets 2.8.10: A portable C++ and Python GUI toolkit

Julian Smart, Robert Roebling, Vadim Zeitlin, Robin Dunn, et al

SetBackgroundColour

----------------------------------

Remarks

The background colour is usually painted by the default wxEraseEvent (p. 571) event handler function under Windows and automatically under GTK. Note that setting the background colour does not cause an immediate refresh, so you may wish to call wxWindow::ClearBackground (p. 1802) or wxWindow::Refresh (p. 1831) after calling this function.

Using this function will disable attempts to use themes for this window, if the system supports them. Use with care since usually the themes represent the appearance chosen by the user to be used for all applications on the system.

SetForegroundColour

----------------------------------

Remarks

The interpretation of foreground colour is open to interpretation according to the window class; it may be the text colour or other colour, or it may not be used at all.

Using this function will disable attempts to use themes for this window, if the system supports them. Use with care since usually the themes represent the appearance chosen by the user to be used for all applications on the system.

James