The my ($var1, $var2, $var3, $var4); has no influence on any of the following lines. Actually context is irrelevant for that line since no assignment is done.

my ($var1, $var2, $var3, $var4);

is only a short form of

(my $var1, my $var2, my $var3, my $var4);

In your example, my ($var1, $var2, $var3, $var4); is used to declare, not assign:

my $var = something;    # declare then assign in scalar context
my ($var) = something;  # declare then assign in list context

...

my ($var1, $var2, $var3, $var4); # declare


$var1 = something1 ; # assign in scalar context
$var2 = something2 ; # assign in scalar context
$var3 = something3 ; # assign in scalar context
$var4 = something4 ; # assign in scalar context
[download]

Hello rnaeye,

my  $var  = something;    # scalar context
my ($var) = something;    # list context
[download]

This is correct, but from the rest of your question it seems you understand this to mean that it is $var which is in first scalar and then list context. Actually, it is something which is evaluated in either scalar or list context. That is, in an assignment, it is the right-hand side which is evaluated in either scalar or list context; the form of the left-hand side determines the context in which the right-hand side is evaluated.

You can use wantarray in a subroutine to see this:

use Modern::Perl;

my  $var1  = context('a');
my ($var2) = context('b');
say for $var1, $var2;
context($var2);

sub context
{
    my $c = (defined wantarray) ?
                    (wantarray  ? 'list' : 'scalar')
                                         : 'void';
    say '(', $_[0], '): is in ', $c, ' context'; 

    return wantarray ? @_ : $_[0];
}
[download]

which outputs:

14:04 >perl 488_SoPW.pl
(a): is in scalar context
(b): is in list context
a
b
(b): is in void context

14:08 >
[download]

Hope that helps,

On the left of the assignment is a scalar variable. A scalar variable on the left of an assignment cries out, "Give me a scalar(single) value to store!" Similarly, an array variable on the left of an assignment:

...cries out, "Give me a list to store!"

Now look at this code:

use strict; 
use warnings; 
use 5.012;

my @something = ('a', 'b', 'c');
my $x = @something;
my($y) = @something;

say $x;
say $y;


--output:--
3
a
[download]

When $x cries out for a single value, the array provides its length. On the other hand, ($y) is a list, and it cries out for a list--so that list assignment can be performed:

my @something = ('a', 'b', 'c');
my $d;
my $e;
my $f;

($d, $e, $f) = @something;
say $d;
say $e;
say $f;

--output:--
a
b
c
[download]

($d, $e) = @something;
say $d;
say $e;

--output:--
a
b
[download]

($d) = @something;
say $d;

--output:--
a
[download]

$d = @something;
say $d;

--output:--
3
[download]

my($s, $t, $u) = @something;
say $s;
say $t;
say $u;

--output:--
a
b
c
[download]