A few problems:

• You mention a URL, and you create a UA object, but you never actually use the UA to retrieve any HTML from the URL.

  Anyway, you don't need to use LWP::UserAgent directly because HTML::TreeBuilder::XPath supplies a new_from_url method.

• You use HTML::Selector::XPath - this module is aimed at turning CSS-style selectors into XPath expressions, but you already have an XPath, so you don't need this module!

• You're using @id and @href within double quotes - this will be interpreted as two Perl arrays! You want to single quote the XPath.

• There shouldn't be a slash at the end of the XPath.

The following works:

use 5.010;
use strict;
use warnings;

use HTML::TreeBuilder::XPath;

my $url  = "http://www.youtube.com/results?search_query=run+flo+rida";
my $tree = HTML::TreeBuilder::XPath->new_from_url($url);

my $xpath = '(//*[@id="search-results"]/li)[1]/div[2]/h3/a/@href';
my @nodes = $tree->findnodes($xpath);

say $_->getValue for @nodes;
[download]

Perhaps using WWW::Mechanize would be helpful in this case:

use strict;
use warnings;
use WWW::Mechanize;

my $mech = WWW::Mechanize->new();
my $url  = 'http://www.youtube.com/results?search_query=run+flo+rida';

$mech->get($url);

my $firstVideo = $mech->find_link( url_regex => qr!/watch\?v=! );

if ( defined $firstVideo ) {
    print 'http://www.youtube.com' . $firstVideo->url;
}
else {
    print "Unable to find link.\n";
}
[download]

Output:

http://www.youtube.com/watch?v=JP68g3SYObU
[download]

HTML::Miner will work too:

use strict                   ;
use warnings                 ;
use HTML::Miner              ;

use Data::Dump qw(dump)      ;

my $mine = new HTML::Miner( 
    CURRENT_URL => 'http://www.youtube.com/results?search_query=run+fl
+o+rida', 
    );

my @links = @{ $mine->get_links() } ;

my @result_links;
foreach my $link ( @links ) { 

    if( $link->{ DOMAIN } =~ 'www.youtube.com' ) { 
    if( $link->{ ANCHOR } =~ /video-time/ ) { 
        if( $link->{ ABS_URL } =~ /http:\/\/www\.youtube\.com(\/watch\
+?v=.*?)$/ ) { 
        push @result_links, $1 ;
        }
    }
    }
}


dump( \@result_links ) ;
[download]

Disclaimer: I maintain that module.

What function? What will work?