#!/usr/bin/perl
use warnings;
use strict;
use feature qw(say);

my %hash;

push(@{$hash{Lemon}}, 'Juice');
push(@{$hash{Lemon}}, 'Cake');
push(@{$hash{Lemon}}, 'Juice');
push(@{$hash{Lemon}}, 'Cake');

my %uniq;
undef @uniq{@{$hash{Lemon}}};
say for keys %uniq;
[download]

Do you really need the array? If not, you can use HoH instead of HoA:

undef $hash{Orange}{Cake};
undef $hash{Orange}{Juice};
undef $hash{Orange}{Cake};
undef $hash{Orange}{Juice};
say for keys %{ $hash{Orange} };
[download]

Seek_Knowledge:

If you're interested in the unique values, I'd suggest adding another level to your hash, something like:

use strict; use warnings;
my %hash;
while (<DATA>) {
    s/\s+$//;
    my ($key1, $key2) = split /\s+/, $_;
    $hash{$key1}{$key2}++;
}
for my $k1 (sort keys %hash) {
    print "$k1: ", join(", ", sort keys %{$hash{$k1}}), "\n";
}
__DATA__
Lemon Juice
Lemon Cake
Apple Cider
Lemon Cake
Apple Butter
Apple Sauce
Apple Juice
Lemon Juice
[download]

Note: The code is untested, but I'd expect output like:

Apple: Butter, Cider, Juice, Sauce
Lemon: Cake, Juice
[download]

...roboticus

When your only tool is a hammer, all problems look like your thumb.

What have you tried so far, and how do the results differ from what you expected?

Absent this information, we can't help you. We could tell you what to do, but that wouldn't help you to learn.