I tend to do:

my %h2; /^cat/ and $h2{ $_ } = $h1{ $_ } for keys %h1;
[download]

Which might be seen as "cheating" as a one-liner; but it is often difficult to put the initialisation of a hash inline.

It is also quite more efficient than map and/or grep for larger hashes, by avoiding the creation of intermediate lists.

%hash2 = map { $_ => $hash{$_} } grep (/^cat/} keys %hash;

# return empty list if ternary test fails....

%hash2 = map { $hash{$_} > 10 ? $_ => $hash{$_} : () } keys %hash;
[download]

You can take a functional approach and chain grep and map on a single line:

#! perl
use strict;
use warnings;
use Data::Dump;

my %h1 = (catastrophe => 1, cataclysm => 2, dogma => 3);
my %h2 = map { $_ => $h1{$_} } grep { /^cat/ } keys %h1;
dd %h2;
[download]

Output:

 1:33 >perl 542_SoPW.pl
("catastrophe", 1, "cataclysm", 2)

 1:37 >
[download]

Hope that helps,

Something like this?

use strict;
use warnings;

use Data::Dumper;

my %orig = (
    cat       => 22,
    dog       => 23,
    category  => 66,
    catalyst  => 77,
    cataclysm => 88,
    dogma     => 89,
    dogstar   => 92,
);

my %cats_only = map { $_ => $orig{$_} } grep /^cat/, keys %orig;

print Dumper \%cats_only;
[download]

$a=key
$b=value
[download]

  DB<142> sub hgrep (&%) { 
           my $f=shift; 
           my @res;
           local ($a,$b); 
           while ( ($a,$b)= splice(@_,0,2) ) { 
             push @res, $a => $b  if $f->() 
           }
           return @res 
          }

  DB<143> %h = ( cat=>0, cut=>1, caty=>2 )
 => ("cat", 0, "cut", 1, "caty", 2)

  DB<144> hgrep { $a =~ /^cat/ } %h
 => ("cat", 0, "caty", 2)

  DB<145> hgrep { $b>1 } %h
 => ("caty", 2)
[download]

UPDATE: see Hash::MostUtils for a similar approach.

Using the perl debugger, for speed and convenience ...

# Lets create a hash that has some similar keys and some unsimilar key
+s 
%h1 = ( cat => 1, dog=> 2, catalog => 3, doggerel => 4 }

x \%h1
0  HASH(0x7f9cb41aaad0)
   'cat' => 1
   'catalog' => 3
   'dog' => 2
   'doggerel' => 4

# See ALL the keys ...
x keys %h1
0  'cat'
1  'doggerel'
2  'catalog'
3  'dog'

# grep allows us to filter that list
x grep { /cat/ } keys %h1
0  'cat'
1  'catalog'

# You access a single hash element with $h{$key}
# You can access multiple elements, called a slice,
# using an array or list of keys. In this case you have to put 
# a '@'  sigil in front, rather than a '$', to indicate 
#you're expecting multiple values
x @h1{grep { /cat/ } keys %h1}
0  1
1  3

# So 'cat' -like keys have the values, '1' and '3'.
# If you wanted to assign those to the keys in 
# another hash, I would save the set of keys in a temp:

@a = grep { /cat/ } keys %h1
@b{@a} = @h1{@a}

  DB<14> x \%b
0  HASH(0x7f9cb41bd0e8)
   'cat' => 1
   'catalog' => 3
[download]

The last bit is saying, create a new hash called 'b' ( we know it's a hash because of how it's elements are being referenced with curly braces ), and create elements for each value in @a, assigning the elements extraced from %h1. You COULD repeat the 'grep' part, once in the LHS and once on the RHS of the assignment, to really get a one-line assignment, but that's messy. While you don't know the order of the elements, it would be the same on each side, but if the set is huge, you don't want to go through all that .. and it's a maintainence problem, and hard to verify the two are identical; so I would split it into two parts.

Ouch!. That creates 5 unneccesary temporary lists and an unneccesary temporary array:

#T1  L2             L1      
@a = grep { /cat/ } keys %h1
#  L5    L4  L3
@b{@a} = @h1{@a}
[download]

---

With the rise and rise of 'Social' network sites: 'Computers are making people easier to use everyday'

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.