lrl1997 has asked for the wisdom of the Perl Monks concerning the following question:

Hi all,

I'd like to do a regex match using perl.

Say I want to search strings containing more than 2 but not more than 3 of a range of characters "ARKYGZX", any letters can be repeats (i.e. AAA, RR, XXK etc) or scattered in the string (i.e. AgoodApeople, XgoodpeopleK, etc), so that as an example, the following strings should be print out as output:

AAgoodpeople

AgoodApeople

XgoodpeopleK

but "ARKYgoodpeopleGZX" shouldn't.

my code is as:

if ($_ =~ /[ARKYGZX]{2,3}/){
    print $_, "\n";
}

[download]

But I think this only works if any of the character are repeats, such as "AAgoodpeople", for strings AgoodpeopleA", or "AXgoodpeople" or "AgoodpeopleX", this code wouldn't work.

Any suggestions?

Thanks

  • Comment on match a range of characters multiple times but they might scattered in the string
  • Download Code

Replies are listed 'Best First'.
Re: match a range of characters multiple times but they might scattered in the string
by toolic (Bishop) on Feb 27, 2013 at 01:10 UTC
    Count the number of matches using m//g: 
    use warnings;
use strict;

while (<DATA>) {
    my @ms = /[ARKYGZX]/g;
    print if @ms == 2 or @ms == 3;
}

__DATA__
AAgoodpeople
AgoodApeople
XgoodpeopleK
ARKYgoodpeopleGZX
goodpeopleGZX

    [download]

    Prints: 

    AAgoodpeople
AgoodApeople
XgoodpeopleK
goodpeopleGZX

    [download]
[reply]
[d/l]
[select]

      Could also count using  tr/// (wish I'd thought of that!). 

      >perl -wMstrict -le
"for my $s (qw(
   AAA RR XXK AxA xAxxYxxRx
   A xAx ARKYGZX XxZxGxYxKxRxA AxAxAxA xYYYYx xRRRRRx RRRR
   )) {
   my $n = $s =~ tr{ARKYGZX}{};
   printf qq{%s match : '%s' \n},
         ($n == 2 || $n == 3) ? '  ' : 'NO', $s;
   }
"
   match : 'AAA'
   match : 'RR'
   match : 'XXK'
   match : 'AxA'
   match : 'xAxxYxxRx'
NO match : 'A'
NO match : 'xAx'
NO match : 'ARKYGZX'
NO match : 'XxZxGxYxKxRxA'
NO match : 'AxAxAxA'
NO match : 'xYYYYx'
NO match : 'xRRRRRx'
NO match : 'RRRR'

      [download]
[reply]
[d/l]
[select]
Re: match a range of characters multiple times but they might scattered in the string
by AnomalousMonk (Archbishop) on Feb 27, 2013 at 01:03 UTC 
    >perl -wMstrict -le
"my $range = quotemeta 'ARKYGZX';
 ;;
 my $rng     = qr{ [$range]  }xms;
 my $not_rng = qr{ [^$range] }xms;
 ;;
 for my $s (qw(
   AAA RR XXK AxA xAxxYxxRx
   A xAx ARKYGZX XxZxGxYxKxRxA AxAxAxA xYYYYx xRRRRRx RRRR
   )) {
   my $match = $s =~ m{
     \A $not_rng* $rng (?: $not_rng* $rng){1,2} $not_rng* \z
     }xms;
   printf qq{%s match : '%s' \n}, $match ? '  ' : 'NO', $s;
   }
"
   match : 'AAA'
   match : 'RR'
   match : 'XXK'
   match : 'AxA'
   match : 'xAxxYxxRx'
NO match : 'A'
NO match : 'xAx'
NO match : 'ARKYGZX'
NO match : 'XxZxGxYxKxRxA'
NO match : 'AxAxAxA'
NO match : 'xYYYYx'
NO match : 'xRRRRRx'
NO match : 'RRRR'

    [download]

    Update: Apply quotemeta directly to  $range initialization, don't use  \Q \E

[reply]
[d/l]
[select]
Re: match a range of characters multiple times but they might scattered in the string
by 7stud (Deacon) on Feb 27, 2013 at 02:00 UTC

    Say I want to search strings containing more than 2 but not more than 3

    Let's see....more than 2...not more than 3, ahhh..................uhmmm.....................(start over) ...ahhhh ..................................uhhmm.........................(1...2...3).............(3..2..1)...............uuhhhh, "What is some number in Normandy, but I just won $75k?"

[reply]

Back to Seekers of Perl Wisdom