or can supply list contexts to its arguments, but it always returns a scalar... or at least, I've never seen it return a list.

use Data::Dumper;
my @A = qw(1 2 3);
my @B = qw(A B C D);
print Dumper(@A or @B);
[download]

In example C, or does return a scalar. You just don't do anything with the scalar. print @list or die is not parsed as print(@list or die); it's parsed as print(@list) or die. Therefore, print only sees the list; it doesn't see the result of the or operator.

Update: meh... the right hand side of or can result in or returning a list:

use Data::Dumper;
my @A = qw();
my @B = qw(A B C D);
print Dumper(@A or @B);
[download]

The left hand side cannot.

print "C:";
for (qq{ab cd}) {
    print /(\S+)/g or die; # prints "C:abcd", list context again
}
print "\n";
[download]

print "C:";
for (qq{ab cd}) {
    print(/(\S+)/g) or die;
}
print "\n";
[download]

print "D:";
for (qq{ab cd}) {
    print /(\S+)/g || die;
}
print "\n";
[download]

my @a = (1,2,3);
print "X:";
print (0 || @a);
print "\n";
print "Y:";
print (@a || 0);
print "\n";
[download]

X:123
Y:3
[download]

After noting that:

The && and || operators differ from C’s in that, rather than returning 0 or 1, they return the last value evaluated.

the Camel Book (4^th Edition, 2012, page 120) goes on to explain that the || operator imposes scalar context on its left operand to facilitate chaining in assignment:

...this has the delightful result that you can select the first of a series of scalar values that happens to be true. Thus, a reasonably portable way to find out the user’s home directory might be:

my $home = $ENV{HOME}
        || $ENV{LOGDIR}
        || (getpwuid($<)[7]
        || die "You're homeless!\n";
[download]

On the other hand, since the left argument is always evaluated in scalar context, you can’t use || for selecting between two aggregates for assignment:

@a = @b || @c;            # This doesn't do the right thing
@a = scalar(@b) || @c;    # because it really means this.
@a = @b ? @b : @c;        # This works fine though.
[download]

(There is a truncated version of this explanation in Logical Defined Or in perlop, but the Camel Book is clearer.)

As tobyink noted above, scalar context is not imposed on the right operand.

Hope that helps,

Athanasius <°(((>< contra mundum

Iustus alius egestas vitae, eros Piratica,

Thanks!