in reply to dos2ux shows cannot open file if it is greater than 2GB size

The classic one liner here is:

perl -pi -e 's/\r\n/\n/' file.raw

which is essentially short for 

#!/usr/bin/perl 
use strict;
use warnings;
use File::Temp qw/ tempfile /;
use File::Copy;

my ($out, $filename) = tempfile("$ARGV[0]_XXXX", UNLINK => 0);

open my $in, '<', $ARGV[0] or die "Open failed: $!";

while (defined(my $line = <$in>)) {
    $line =~ s/\r\n/\n/;
    print $out $line;
}

close $in;
close $out;
move($filename, $ARGV[0]);

[download]

See -e, -p and -i in perlrun, and review perlretut for details on regular expressions.

#11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.

Replies are listed 'Best First'.
Re^2: dos2ux shows cannot open file if it is greater than 2GB size
by ikegami (Patriarch) on Mar 13, 2013 at 17:44 UTC
    It's closer to 
    open(my $in, '<', $ARGV[0]) or die $!;
unlink($ARGV[0]);

open(my $out, '>', $ARGV[0]) or die $!;
while (<$in>) {
   s/\r\n/\n/;
   print($out $_);
}

    [download]
[reply]
[d/l]

      Thanks Buddy...It works fine.

      But it takes time to complete.

[reply]

        You can actually optimize the regular expression using a string termination anchor: s/\r$// That keeps it from having to check the entire string.

        #11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.

[reply]
[d/l]
        To speed things up, I'd read more at a time. 
        perl -pe'BEGIN { $/ = \(1024*1024); } s/\r//g;' file.in >file.out

        [download]
        But yeah, it will take time to copy 7GB.
[reply]
[d/l]

In Section Seekers of Perl Wisdom