This seems to be a question about finding all possible paths through a graph that end in "24". This does the job:

use strict;
use warnings;

use Graph::Directed;

my $g = "Graph::Directed"->new;

$g->add_edge(split ":") for qw(
    0:6
    0:12
    0:18
    0:24
    6:12
    6:18
    6:24
    12:18
    12:24
    18:24
);

# This doesn't protect against cyclic graphs
sub paths_from_vertex
{
    my $g = shift;
    my $v = shift;
    return unless $g->has_vertex($v);
    my @s = $g->successors($v);
    return [$v] unless @s;
    my @p = map { paths_from_vertex($g, $_) } @s;
    unshift @$_, $v for @p;
    return @p;
}

sub print_path
{
    my @path = @{+shift};
    for my $i ( 0 .. $#path-1 )
    {
        print "$path[$i]:$path[$i+1] ";
    }
    print "\n";
}

for my $i (0..24)
{
    print_path($_) for paths_from_vertex($g, $i);
}
[download]

This appears to do exactly what I needed. Thank you for your reply.

Title probably doesn't accurately describe the issue

I think what you are looking for is known combinatorially as 'non-overlapping subsets'.

Should be fun to generate.

my @input = qw(0:6
0:12
0:18
0:24
6:12
6:18
6:24
12:18
12:24
18:24);

my %link;
for (@input) {
    my ($key, $value) = split /:/;
    push @{$link{$key}}, $value;
}
[download]

$VAR1 = {
          '6' => [
                   '12',
                   '18',
                   '24'
                 ],
          '18' => [
                    '24'
                  ],
          '0' => [
                   '6',
                   '12',
                   '18',
                   '24'
                 ],
          '12' => [
                    '18',
                    '24'
                  ]
        };
[download]

You then just need to connect the dots, which I'd probably implement with a recursive subroutine.

Note that the confusion about the start and end definition of your chains likely comes from the fact that, in your example, you seem to use all possible values for starts, but only 24 as an end.

I hope this all makes sense and thanks in advance for any help or insight!

not really.. at least to me...

Which values are considered "starting" and which are considered "ending?"

Each item in the array is a starting and ending value (colon delimited), so in the above example $VAR1 = 0:6, 0 is the starting value and 6 is the ending value, and so on for each array item.

G'day jaiieq,

I appear to have identified more paths than you show (e.g. 0:6 6:12 12:24 is not in your list). Here's the code:

#!/usr/bin/env perl -l

use strict;
use warnings;

my %route_from;
my %routes_starting_at;
my @paths = qw{0:6 0:12 0:18 0:24 6:12 6:18 6:24 12:18 12:24 18:24};
map { push @{$route_from{$_->[0]}}, $_->[1] } map { [ split /:/ ] } @p
+aths;

for my $s (sort { $b <=> $a } keys %route_from) {
    for my $e (sort { $a <=> $b } @{$route_from{$s}}) {
        my $path = "$s:$e";

        if (exists $routes_starting_at{$e}) {
            for my $r (@{$routes_starting_at{$e}}) {
                my $ext_path = join ' ' => $path, $r;
                push @{$routes_starting_at{$s}}, $ext_path;
            }
        }
        else {
            push @{$routes_starting_at{$s}}, $path;
        }
    }
}

for my $k (sort { $a <=> $b } keys %routes_starting_at) {
    print for @{$routes_starting_at{$k}};
}
[download]

Output:

$ pm_start_end_graph.pl
0:6 6:12 12:18 18:24
0:6 6:12 12:24
0:6 6:18 18:24
0:6 6:24
0:12 12:18 18:24
0:12 12:24
0:18 18:24
0:24
6:12 12:18 18:24
6:12 12:24
6:18 18:24
6:24
12:18 18:24
12:24
18:24
[download]