Doctrin has asked for the wisdom of the Perl Monks concerning the following question:

Hello dear Monks. I have this: 
my @arrOfJoiners = ('!','*','?');
my @arrToJoin = (1,2,3,4);

[download]
I wanna have this: 1!2*3?4 Surely, I could make something like: 
my @arrOfJoiners = ('!','*','?');
my @arrToJoin = (1,2,3,4);
my $s;
for my $arrElem (@arrToJoin) {
    $s .= $arrElem . (shift @arrOfJoiners);
}
print $s;

[download]
But, is there a smarter way to do it using, say, "join" ? Maybe, even one-liner?.. Thanks in advance. ====UPD==== Oh, looks like I got it: 
$s = join "", (map {$_ . (shift @arrOfJoiners)} @arrToJoin);

[download]
Thanks, I think this would be fine.

Replies are listed 'Best First'.
Re: Joining array with elements of another array
by tobyink (Canon) on Mar 18, 2013 at 16:12 UTC

    Non-destructive; look ma, no List::MoreUtils...

    use v5.12;

my @arrOfJoiners = ('!','*','?');
my @arrToJoin = (1,2,3,4);

say join "", map(($arrToJoin[$_], $arrOfJoiners[$_]), 0..$#arrToJoin);

    [download]
    package Cow { use Moo; has name => (is => 'lazy', default => sub { 'Mooington' }) } say Cow->new->name
[reply]
[d/l]
Re: Joining array with elements of another array
by toolic (Bishop) on Mar 18, 2013 at 15:49 UTC
    Another, albeit clumsy, way is to use List::MoreUtils 
    use warnings;
use strict;
use List::MoreUtils qw(mesh);

my @arrOfJoiners = ('!','*','?');
my @arrToJoin = (1,2,3,4);
my @arr2 = mesh(@arrToJoin, @arrOfJoiners);
pop @arr2;
print join('', @arr2), "\n";

__END__

1!2*3?4

    [download]

    Maybe the source code for mesh will give you other ideas.

[reply]
[d/l]

      If the list is small enough that one doesn't mind the implicit temporary copy of joiners, this might seem a little more elegant, and still uses mesh (otherwise known as zip.

      use List::MoreUtils qw(zip);

my @arrOfJoiners = ('!','*','?');
my @arrToJoin = (1,2,3,4);


my $string = join '', zip @arrToJoin, @{[ @arrOfJoiners, '' ]};

print "$string\n";

      [download]

      If the list of joiners is potentially huge, it would be better just to push an empty string to the end of the array:

      use List::MoreUtils qw(zip);

my @arrOfJoiners = ('!','*','?');
my @arrToJoin = (1,2,3,4);

push @arrOfJoiners, ('') x ( @arrToJoin - @arrOfJoiners );
my $string = join '', zip @arrToJoin, @arrOfJoiners;
print "$string\n";

      [download]

      Dave

[reply]
[d/l]
[select]
Re: Joining array with elements of another array
by Anonymous Monk on Mar 18, 2013 at 15:23 UTC

    Is there a smart way to do it using, say, "join" ? Thanks in advance.

    No, join is simple

[reply]

Back to Seekers of Perl Wisdom