I think the logic you want is:

if ($start_input =~ /\d\d\d\d\.\d\d/ && $end_input =~ /\d\d\d\d\.\d\d/
+) {
   ...;
}
elsif ($start_input =~ /\d\d\d\d/ && $end_input =~ /\d\d\d\d/) {
   ...;
}
[download]

This is because you've got two conditionals which overlap. Test specific conditions before generic ones. Compare:

use v5.12;

my $name = "Toby";

{
    say "FIRST BLOCK";
    
    if    ($name =~ /^T/)    { say "name starts with T" }
    elsif ($name =~ /^Toby/) { say "name is Toby" }
    
    say "END BLOCK";
}

{
    say "SECOND BLOCK";
    
    if    ($name =~ /^Toby/) { say "name is Toby" }
    elsif ($name =~ /^T/)    { say "name starts with T" }
    
    say "END BLOCK";
}
[download]

The "name starts with T" test is more generic than the "name is Toby" test, so if you perform the "name starts with T" test first, it will effectively swallow up the other test.

I added a few comments to your script. I don't exactly know what outcome you want, but I do spot a few things that are most likely errors.

#!/usr/bin/perl -w

use strict;
use locale;
use warnings;
use diagnostics;
use utf8;

binmode(STDIN,  ":encoding(utf8)");  # prepend the colon to "encoding"
+.
binmode(STDOUT, ":encoding(utf8)");  # prepend the colon to "encoding"
+.
binmode(STDERR, ":encoding(utf8)");  # prepend the colon to "encoding"
+.

my $data_file = "data.txt";
my ($start, $end);

# Warning: this works, but DATA is special.  Better to use a different
+ name.
open (DATA, '<:utf8', $data_file) || die "Couldn't open $data_file : $
+!\n";

# Consider using IO::Prompt::Tiny, or IO::Prompt::Hooked.
print "Start time (format : yyyy.mm.dd.hh):\n";
chomp (my $start_input = <STDIN>);

print "End time (format : yyyy.mm.dd.hh):\n";
chomp (my $end_input = <STDIN>);

# Questionable: Are you really intending to pass any input that contai
+ns four
# contiguous digits?  Maybe so, but seems like an inadequate validatio
+n.
if ($start_input =~ /\d\d\d\d/ && $end_input =~ /\d\d\d\d/){
  while (<DATA>){
    # Even more questionable: None of your suggested input formats wou
+ld match.
    # Did you mean $start_input =~ /\d{6}/ ?  When would the input eve
+r have
    # six contiguous digits?
    if (/$start_input\d\d\d\d\d\d/ .. /$end_input\d\d\d\d\d\d/){
      if ($_ =~ /(.*)\t(.*)\t(.*)/){
        print "Date  = $1" . "\t" . "Temp_moy_DegCs = $2" . "\t" . "HR
+_moy_s = $3\n";
      }
    }
  }
}

if ($start_input =~ /\d\d\d\d\.\d\d/ && $end_input =~ /\d\d\d\d\.\d\d/
+){
  # Maybe you intended to do this immediately after receiving input.  
+That would
  # fix the second "if", but would break the fourth "if" conditional.
  $start_input =~ tr/\.//d;
  print "$start_input\n";
  $end_input =~ tr/\.//d;
  print "$end_input\n";
  while (<DATA>){
    # I don't see this ever working.  Did you mean $start_input =~ /\d
+{4}/ .. ?
    if (/$start_input\d\d\d\d/ .. /$end_input\d\d\d\d/){
      if ($_ =~ /(.*)\t(.*)\t(.*)/){
        print "Date  = $1" . "\t" . "Temp_moy_DegCs = $2" . "\t" . "HR
+_moy_s = $3\n";
      }
    }
  }
}

close (DATA);
[download]

I'm guessing the problem is when you enter yyyy the code runs in both the yyyy and the yyyy.mm blocks. Either add start ^ and end $ anchors to the regex statements

if ($start_input =~ /^\d\d\d\d$/ && $end_input =~ /^\d\d\d\d$/){
[download]

or swap the order so the if yyyy.mm is first then elseif yyyy

Describe what the script is supposed to do. It's not clear to me from briefly inspecting the code. I don't understand the intended logic.

I actually got it by experimenting with the code. I wanted to give a user different levels of control. The goal was to display the content of the second and the third between two dates. And the user could choose to input, the year, the month, the day, the hour or all of them.

I just had to add "^" and "$" in the first regex in order to mark the beginning and the end of the string :

elsif ($start_input =~ /^\d\d\d\d\.\d\d\.\d\d\.\d\d$/ && $end_input =~
+ /^\d\d\d\d\.\d\d\.\d\d\.\d\d$/){
    $start_input =~ tr/\.//d;
    print "$start_input\n";
    $end_input =~ tr/\.//d;
    print "$end_input\n";
    while (<DATA>){
        if (/$start_input/ .. /$end_input/){
            if ($_ =~ /(.*)\t(.*)\t(.*)/){
                print "Date  = $1" . "\t" . "Temp_moy_DegCs = $2" . "\
+t" . "HR_moy_s = $3\n";
            }
        }
    }
}
[download]

it seems to work now.