Strange interaction of bigint and foreach

Athanasius has asked for the wisdom of the Perl Monks concerning the following question:

Hi,

I’ve been using the exponentiation operator ** in conjunction with the bigint pragma to generate large integral powers, which I need to be exact. After some debugging, I found the following:

#! perl
use strict;
use warnings;
use bigint;

print "\nWith two foreach loops:\n\n";

for my $i (12 .. 14)
{
    for my $j (20 .. 22)
    {
        print $i ** $j, "\n";
    }
}

print "\nWith an inner C-style for loop:\n\n";

for my $i (12 .. 14)
{
    for (my $j = 20; $j <= 22; ++$j)
    {
        print $i ** $j, "\n";
    }
}
[download]

Output:

22:38 >perl 604_SoPW.pl

With two foreach loops:

3.83375999244748e+021
4.60051199093697e+022
5.52061438912436e+023
1.90049637748808e+022
2.4706452907345e+023
3.21183887795486e+024
8.36682554252848e+022
1.17135557595399e+024
1.63989780633558e+025

With an inner C-style for loop:

3833759992447475122176
46005119909369701466112
552061438912436417593344
19004963774880799438801
247064529073450392704413
3211838877954855105157369
83668255425284801560576
1171355575953987221848064
16398978063355821105872896

22:38 >
[download]

As you can see, the inner foreach loop is somehow cancelling the effect of the use bigint pragma; but converting that loop into a C-style for loop fixes the problem and gives me the output I need.

So, what’s going on? Is this behaviour documented anywhere? Is it a bug?

Thanks,

Athanasius <°(((>< contra mundum Iustus alius egestas vitae, eros Piratica,

Comment on Strange interaction of bigint and foreach Select or Download Code

Replies are listed 'Best First'.

Re: Strange interaction of bigint and foreach
by moritz (Cardinal) on Apr 11, 2013 at 12:58 UTC

What happens is that the range operator .. is not overloadable. bigint works by overloading operators and literals, and since .. is not overloadable, it can't make bigint ranges work. And, more to the point here, the variables coming out of iterating a range are normal ints, and not bigints.

This is a known limitation, over which I've also stumbled in the past. I don't know if it's documented somewhere; if not, it really should be. Update: I've submitted a doc patch which mentions this problem in bigint.pm and overload.pm. Second Update: patch accepted, so perl 5.18 will contain the updated documentation.

Perl 6 - the future is here, just unevenly distributed

[reply]
[d/l]

Re^2: Strange interaction of bigint and foreach

by hdb (Monsignor) on Apr 11, 2013 at 13:09 UTC

Very strange and dangerous... Some workarounds:

use strict;
use warnings;
use bigint;

print "\nWith two foreach loops:\n\n";

for my $j (20 .. 22)
{
    for my $i (12 .. 14)
    {
        print $i ** ($j+0), "\n";
    }
}

print "\nWith two foreach loops:\n\n";

for my $j (20 .. 22)
{
    for my $i (12 .. 14)
    {
        print (((0+$i) ** $j), "\n");
    }
}

print "\nWith two foreach loops:\n\n";

for my $j (20 .. 22)
{
    for my $i (12 .. 14)
    {
        print ((0+$i) ** ($j+0), "\n");
    }
}
[download]

[reply]
[d/l]

Re: Strange interaction of bigint and foreach
by Athanasius (Archbishop) on Apr 11, 2013 at 13:14 UTC

Thanks to all for the quick responses! I was misled by the documentation for bigint, which begins:

All operators (including basic math operations) are overloaded.

Chalk this one up to experience! (But I have to say: Apart from this glitch, I’m finding bigint to be brilliant at what it does.)

Cheers,

Athanasius <°(((>< contra mundum Iustus alius egestas vitae, eros Piratica,

[reply]
[d/l]

Re: Strange interaction of bigint and foreach
by salva (Canon) on Apr 11, 2013 at 13:02 UTC

~~probably caused by the compiler optimizing the foreach(<constant range>) {} construction into a C-like loop internally in order to reduce memory usage.~~

You can try reporting it to p5p.

update: Even if the problem is the range operator, this is still IMO a bug in Perl. The range operator should be overloadable or at least it should use the overloaded + and < operators.

[reply]
[d/l]
[select]