Long-overdue, but I have a working version! I had to:

• Use the latest Curses::UI (v0.9629) with the fix from rt://50142 (here)
• Use only custom colors --- don't try to combine custom colors with standard colors
• Set the color on the Curses::UI instance, the window, and every widget

Et voila, a curses UI with an orange background and white text (tested on Perl 5.26):

use strict;
use warnings;
use Curses::UI '0.9609';

my $cui = Curses::UI->new( -color_support => 1, -clear_on_exit => 1 );
$cui->set_binding( sub { $cui->mainloopExit() }, "\cC" );

# Colors
my $co = $Curses::UI::color_object;
$co->define_color( 'wh', 999, 999, 999 );    # range [1, 999]
       # For some reason, I don't seem to be able to mix
       # standard colors with custom colors.
$co->define_color( 'orange', 999, 599, 1 );
my $FG     = 'wh';
my $BG     = 'orange';
my @COLORS = (
    ( map { ; $_ => $BG } qw(-bg -tbg -bbg -sbg) ),
    ( map { ; $_ => $FG } qw(-fg -tfg -bfg -sfg) )
);

$cui->set_color_fg($FG);
$cui->set_color_bg($BG);

# Widgets
my $win = $cui->add(
    'main-window', 'Window',
    -border         => 1,
    -title          => "Ce n'est pas une fenetre",
    -titlefullwidth => 1,
    @COLORS,
);

$win->add(
    'help', 'Label',
    -y             => 1,
    -width         => -1,
    -reverse       => 1,
    -paddingspaces => 1,
    -text          => "Howdy!  Press Ctl-C to exit.",
    @COLORS,
);

$cui->mainloop;
$cui->leave_curses;
[download]

G'day return0,

While the Curses::UI::Color documentation is accurate when it says "The RGB values can be between 0 and 1000.", it's misleading as it doesn't indicate that's an exclusive range: the actual range of numbers available to you is 1..999.

A pragmatic solution would be to use 1 instead of 0: the difference in colour would be imperceptible to the human eye. Alternatively, if the exact colour is important, you could modify the module.

More as an afterthought, it's possible the RGB values you need for orange are more like 999,599,1 (I think 255,155,0 would be very dark). I'll leave you to experiment.

oh thank you! I didn't even look at the source code for this yet;I was really busy yesterday. I see it now:
 return unless $b > 0;
Okay, I get it, and you're right about not seeing the difference, I remember that from Steganography 101. You guys are the best! thank you! :D

doc says its a method, source code confirms , see for yourself

sub define_color {
    my $this = shift;
    my $name = shift;
    my ($r, $g, $b) = @_;

    return unless $r < 1000;
    return unless $g < 1000;
    return unless $b < 1000;
    
    return unless $r > 0;
    return unless $g > 0;
    return unless $b > 0;

    init_color($this->{ccount}, $r, $g, $b);

    $this->{cmap}->{$name} = $this->{ccount};
    $this->{ccount}++;

    return 1;
}
[download]

http://cpansearch.perl.org/src/MDXI/Curses-UI-0.9609/examples/demo-color shows a global color object you can use to define additional colors my $co = $Curses::UI::color_object;

so  $Curses::UI::color_object->define_color(qw/ lorange 255 155 0 /);

http://search.cpan.org/grep?cpanid=MDXI&release=Curses-UI-0.9609&string=default&i=1&n=1&C=0, http://search.cpan.org/grep?cpanid=MDXI&release=Curses-UI-0.9609&string=define_color&i=1&n=1&C=0, http://search.cpan.org/dist/Curses-UI/MANIFEST

Unfortunately that doesn't seem to work.


my $cui = new Curses::UI(-color_support=>1); # create a curses object
my $co = $Curses::UI::color_object;
$Curses::UI::color_object->define_color('orange',255,140,1);
[download]

Doesn't return an error, but doesn't make any color - it just goes white. :( Is my code wrong? Thanks, ~return0