You seem to be using some modules to do your work. Could you please specify which they are. The code below is just rephrasing your snippet and loads the data into a hash.

use strict;
use warnings;
use Data::Dumper;
my %data = map {
        s/#.*//;  # remove comments
        s/^\s+//; # remove leading white space
        s/\s+$//; # remove trailing white space
        m/(.*?)\s*=\s*(.*)/; # split on =, ignoring surrounding spaces
} <DATA>;
print Dumper(%data);

__DATA__
NAME=John Smith
AGE=15
RANK=Tier 1
URL=http://somesite.com
[download]

What is missing is probably something like my $record = REC->new( %data ); but I cannot test this hypothesis as I don't where REC comes from. Hope this helps...

I'm using File::Slurp

#!/usr/bin/perl
use strict;
use warnings;
use File::Slurp;
use Data::Dumper;
$file="config.txt";

my %record =map{
s/#.*//;
s/^\s+//;
s/\s+$//;
m/(.*?)\s*=\s*(.*)/;
} read_file($file);

print Dumper (\%record);
[download]

The dump from my code is

$VAR1={
                 'Name' =>John Smith',
                 'URL' => '15',
                 'RANK' => 'Tier 1',
                 'URL' => 'http://somesite.com'
               };
[download]

but when the data is in the code, the dump is

$VAR1= bless( {
                 'Name' =>John Smith',
                 'URL' => '15',
                 'RANK' => 'Tier 1',
                 'URL' => 'http://somesite.com'
               }, 'REC' );
[download]

You are also having REC->new which must be provided by some module. Which one is that?

++hdb (x4) for persevering while bits of information were slowly revealed.

You can probably instantiate your REC objects like this:

my $record = REC::->new(
    map { s/#.*$//; /^\s*([^=]+)=(.*?)\s*$/ ? ($1, $2) : () } read_fil
+e($file)
);
[download]

Here's my test:

$ perl -Mstrict -Mwarnings -e '
    my $raw_data = q{
        # Some comment
        NAME=John Smith
        AGE=15 # years only!
        RANK=Tier 1
        URL=http://somesite.com
        URI=http://example.com
    };
    package REC;
    my @req_args = qw{NAME AGE RANK URL};
    sub new {
        my ($class, %args) = @_;
        exists $args{$_} or die "FAILED: $_" for @req_args;
        bless { %args } => $class;
    }
    sub print_for_config {
        my $self = shift;
        print "$_=", $self->{$_}, "\n" for @req_args;
    }
    package main;
    print "=" x 20, "\nDATA IN\n", "=" x 20, "\n$raw_data\n";
    my $record = REC::->new(
        map { s/#.*$//; /^\s*([^=]+)=(.*?)\s*$/ ? ($1, $2) : () }
            split /\n/ => $raw_data
    );
    print "=" x 20, "\nDATA OUT\n", "=" x 20, "\n";
    $record->print_for_config;
'
====================
DATA IN
====================

        # Some comment
        NAME=John Smith
        AGE=15 # years only!
        RANK=Tier 1
        URL=http://somesite.com
        URI=http://example.com
    
====================
DATA OUT
====================
NAME=John Smith
AGE=15
RANK=Tier 1
URL=http://somesite.com
[download]

If you use strict and warnings, you can avoid code like this:

my record =map{
[download]

I'll also draw your attention to the following guidelines:

• How do I compose an effective node title?
• How do I post a question effectively?