Like this:

my $x=0;
my $size=5;
for( my $i=0; $i<$size; $i+=2,$x++ ) {
        print "$i:$x\n";
}
[download]

or

my $x=0;
my $size=5;
for( my $i=0; $i<$size; $i+=2 ) {
        print "$i:",$x++,"\n";
}
[download]

It's also possible to define (and initialize, if needed) two (or more) lexical loop variables entirely locally:

for (my ($i, $n) = (1, 2);  $i < $limit;  $i += 2, ++$n) {
    do_something_with($i, $n);
    }
[download]

while( something ) {
   $anything++;
   $you += 2;
   $want += 11teen;
}
[download]

Definitely.

Don’t make it clever .. always make it clear.   The odds are always good that someone (else) will come behind you and have to modify that piece of code.   Make it obvious what the code does, and easy to change it.

Naturally there's always more than one way to do it.

Your way (for loop):

for (                       # Lexical scope
  my($idx,$x,$y)=(0,0,0);   # Initializer
  $idx<10;                  # Condition
  ++$idx, $x+=2, $y+=3      # Prep for next iteration.
) {
  print "$idx, $x, $y\n";
}
[download]

...which is exactly the same as (while loop):

{                                     # Lexical scope
  my( $idx, $x, $y ) = ( 0, 0, 0 );   # Initializer
  while( $idx < 10 ) {                # Condition
    print "$idx, $x, $y\n";
  }
  continue {                          # Prep for next iteration.
    ++$idx;
    $x += 2;
    $y += 3;
  }
}
[download]

It's up to you to decide which is more legible and maintainable. I think probably the while loop. Both loops are explicit in what they do, but the while loop, with its "continue" block is visually striking so that the fact that several variables are being incremented is not so easy to miss.

Both are probably proof that it's possible to write C in Perl. ;) But I can't think of a more elegant approach at the moment. I guess that must say something about where I've been spending too much time.

Update: By the way, if you pass the above code samples through B::Deparse, you'll find that they decompose almost identically:

$ perl -MO=Deparse,-x9 ./mytest.pl

# Decomposition of the "for" loop:
while ($idx < 10) {
    print "$idx, $x, $y\n";
}
continue {
    ++$idx, $x += 2, $y += 3
}

# Decomposition of the "while" loop (essentially it's unchanged):
{
    my($idx, $x, $y) = (0, 0, 0);
    while ($idx < 10) {
        print "$idx, $x, $y\n";
    }
    continue {
        ++$idx;
        $x += 2;
        $y += 3;
    }
}
./mytest.pl syntax OK
[download]