If you can be sure that the FROM field never contains a string resembling the following DATE field, you can take this approach:

#! perl
use strict;
use warnings;

<DATA>;     # Discard header

while (<DATA>)
{
    chomp;
    my @tokens = split /\s+/;
    my @fields;

    for (my $i = 0; $i < @tokens; ++$i)
    {
        if ($i == 2)
        {
            my $from = $tokens[$i];

            until ($tokens[++$i] =~ m! ^ \d{1,2} / \d{1,2} $ !x)
            {
                $from .= ' ' . $tokens[$i];
            }

            push @fields, $from;
        }

        push @fields, $tokens[$i];
    }

    print join('|', @fields), "\n";    
}

__DATA__
REQID     DEST             FROM                     DATE   TIME    nPa
+ges  RCV
138454  mail_room     Marco's Pizza         12/26 21:52    1  rcv     
138446  custsvc      973 618 0577          12/26 18:44    1  rcv     
138445  county2       spam                  12/26 18:41    3  rcv     
138444  custsvc      spam                  12/26 18:30    1  rcv
138439  county2       7182737253            12/26 17:54    2  rcv     
138438  county2       Acme Products, Inc.   12/26 17:52    1  rcv
[download]

Output:

14:30 >perl 614_SoPW.pl
138454|mail_room|Marco's Pizza|12/26|21:52|1|rcv
138446|custsvc|973 618 0577|12/26|18:44|1|rcv
138445|county2|spam|12/26|18:41|3|rcv
138444|custsvc|spam|12/26|18:30|1|rcv
138439|county2|7182737253|12/26|17:54|2|rcv
138438|county2|Acme Products, Inc.|12/26|17:52|1|rcv

14:30 >
[download]

Update: If you know that only the third field can contain spaces, a better approach may be as follows:

1. shift @fields twice to get the first two fields
2. pop   @fields four times to get the last four fields
3. join(' ', @fields) to get the third, remaining field.

Update 29^th April: Tidied the code.

Hope that helps,