Already demonstrated:

Nope! Jump-labels only change each time with_return constructs are called to avoid confusion if they are dynamically nested.

Here is example. Try do same with "goto"

use strict;
use warnings;
use Return::MultiLevel qw/with_return/;
sub rec
{
        my ($i, $return) = (@_, undef);
        $i++;
        print "i=$i\n";
        if ($i == 3) {
                with_return {
                        my $newreturn = shift;
                        rec($i, $newreturn);
                };
        }
        if ($i == 5) {
                 $return->() if $return;
        }
        if ($i == 7) {
                return;
        }
        rec($i, $return);
}

rec(0);

__END__

$ perl ml.pl 
i=1
i=2
i=3
i=4
i=5
i=4
i=5
i=6
i=7
[download]

> Here is example.

Well this is far beyond what the OP wanted!

And your $return->() if $return clause makes it quite esoteric ...

> Try do same with "goto"

... FWIW!

use strict;
use warnings;
our $target="";

sub rec {
  my ($i) = @_;
  $i++;
  print "i=$i $target\n";
  if ($i == 3) {
    target($i);
  }
  if ($i == 5) {
    goto $target if $target;
  }
  if ($i == 7) {
    return;
  }
  rec($i);
}

sub target {
  local $target="TARGET";
  rec(shift);
 TARGET:
}

rec(0);

__END__

i=1 
i=2 
i=3 
i=4 TARGET
i=5 TARGET
i=4 
i=5 
i=6 
i=7
[download]

As I said it's only an abstraction of the goto mechanism!

Good night! =)

Cheers Rolf

( addicted to the Perl Programming Language)

Well this is far beyond what the OP wanted!

Why do you think so? he mention call stack:

but to a higher point up the call stack.

Your code is a bit cheat - you implemented another subroutine, just to remember point in the stack. In my code, during executiom, there was just one "longjump" always to same point, so you had to implement just one subroutine with one label. But in general case you need N goto lables (N is unknown at compilation stage), so it's impossible without eval EXPR (not eval BLOCK)
Try this,

use strict;
use warnings;
use Return::MultiLevel qw/with_return/;
our %returns;

sub rec
{
    my ($i) = @_;
    $i++;
    print ">> i=$i\n";

    if ($i <= 9) {
        with_return {
            $returns{$i} = shift;
            rec($i);
        };
    }

    if (@ARGV) {
        my $r = shift @ARGV;
        print "RESTORE $r\n";
        $returns{$r}->();
    }

    print "<< i=$i\n";
}

rec(0);

__END__
[download]

$perl ml_a.pl 6
>> i=2
>> i=3
>> i=4
>> i=5
>> i=6
>> i=7
>> i=8
>> i=9
>> i=10
RESTORE 6
<< i=6
<< i=5
<< i=4
<< i=3
<< i=2
<< i=1
[download]

$perl ml_a.pl 3
>> i=1
>> i=2
>> i=3
>> i=4
>> i=5
>> i=6
>> i=7
>> i=8
>> i=9
>> i=10
RESTORE 3
<< i=3
<< i=2
<< i=1
[download]

And let's consider @ARGV as external input, which is available only just before program go to 'RESTORE' point, but not before program started a recursion