Hello rahularora, and welcome to the Monastery!

Here is one way:

#! perl
use strict;
use warnings;

my @fields = (42, undef, 'abc', undef, 'foo', 'bar');
my $flags  = 0;
my $mask   = 0b1000_0000;

for my $field (@fields)
{
    $flags |= $mask if defined $field;
    $mask >>= 1;
}

printf "%08b\n", $flags;
[download]

Output:

13:35 >perl 640_SoPW.pl
10101100

13:36 >
[download]

See Bitwise String Operators and Shift Operators.

Hope that helps,

Thanks for quick reply. This forum is best forum for any perl related queries.and you peoples are very helpful.

I have some 6 field say field 1,field 2,field 3,field 4,field 5,field 6.

You'll have to clarify what you mean by "field"?

Are these substrings within a single string? Or entryfields within an HTML form? Columns in a CSV file?

And also what you mean by "blank"?

Let's say that you have captured the fields into an array, then you might build you binary value this way:

my @fields = ... ;

my $binary = chr(0);
defined( $fields[ $_ ] ) && length( $fields[ $_ ] ) and vec( $binary, 
+$_, 1 ) = 1 for 0 .. $#fields;
[download]

For example:

@fields = ( 'fred', undef, '', 0, 123, '  ' );;
$binary = '';;

vec( $binary, $_, 1 ) = ($fields[ $_ ] // '' ) =~ /\S/ ? 1 : 0 for 0 .
+. $#fields;;

print unpack 'b*', $binary;;
10011000
[download]

Here is another solution based on map and join:

use strict;
use warnings;

my @fields = ( 1, "", undef, "0", "blah", 5 );
my $output = join "", map { length($_) ? 1 : 0 } @fields[0..7];
print "$output\n";
[download]

map allows you to apply the test for a field being blank to each element of your fields array. I have used length but you can plug in any other test you deem appropriate. map will in this case return an array of 0s and 1s which is then joined into a string.

From your question it seems that you want to get an answer of length 8, so I have expanded @fields by two (blank) fields using @fields[0..7]. If I mis-read this part of your question, just remove the [0..7] bit.