G'day Dr Manhattan,

You were almost there. You need to push an arrayref (not an array) of the split characters. Here's my test:

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Dumper;

my @MainArray;

while (<DATA>) {
    chomp;
    push @MainArray, [ split // ];
}

print Dumper \@MainArray;
 
__DATA__
Hello
my
name
is
Jack
[download]

Output:

$ pm_file_chars_to_AoA.pl
$VAR1 = [
          [
            'H',
            'e',
            'l',
            'l',
            'o'
          ],
          [
            'm',
            'y'
          ],
          [
            'n',
            'a',
            'm',
            'e'
          ],
          [
            'i',
            's'
          ],
          [
            'J',
            'a',
            'c',
            'k'
          ]
        ];
[download]

See also: perldsc - Perl Data Structures Cookbook

Thanks that works great! Next question- How do I reference an element if I want to splice it?

my $length = $#MainArray;                              
for (my $x = 0; $x <= $length; $x++)                                  
+    
{
    my $smallLength = $MainArray[$#$x];
    for(my $q = 0; $q <= $smallLength; $q++)
    {
        my $element = $MainArray[$x][$q];
        if(some if statement concerning $element)                    
        {
            splice(How do I reference this part?); 
        }
    }
}
[download]

I see hdb has shown the syntax you requested. Be aware that splice can be slow and there are often better alternatives. For instance, if you had intended to use splice to remove lowercase characters, you could have rewritten that entire block of code above as:

for (@MainArray) {
    @$_ = grep { ! /[a-z]/ } @$_;
}
[download]

Here's my test:

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Dumper;

my @MainArray;

# Original array populating code
while (<DATA>) {
    chomp;
    push @MainArray, [ split // ];
}

# New alternative to 'splice' code
for (@MainArray) {
    @$_ = grep { ! /[a-z]/ } @$_;
}

print Dumper \@MainArray;

__DATA__
Hello
my
name
is
Jack
[download]

Output:

$ pm_file_chars_to_AoA_2.pl
$VAR1 = [
          [
            'H'
          ],
          [],
          [],
          [],
          [
            'J'
          ]
        ];
[download]

-- Ken

splice( @{ $MainArray[$x] }, $q, 1 );
[download]

open (A1, "<2 normaal.txt") or die "can't open";

my @MainArray;

while (<A1>)
{
    my $in = $_;
    chomp $in;
    push (@array1, split(//, $in));
}
[download]

Another way to do it:

open my $A1, '<', '2 normaal.txt' or die "can't open '2 normaal.txt' b
+ecause: $!";

my @MainArray;

while ( my $in = <$A1> ) {
    push @MainArray, [ $in =~ /[[:alpha:]]/g ];
}
[download]

You nearly had it:

push @MainArray, [ split(//, $in) ];
[download]

Or as a one-liner:

my @MainArray = map { chomp; [ split // ] } <A1>;
[download]

UPDATE: or even

my @MainArray = map [ /(.)/g ], <A1>;
[download]