Re: Perl Tk - how to send a value from a subroutine back to the main program using Button

In order to do this you need to pass around a reference. Here's a working (albeit barebones) script to demonstrate this:

#!/usr/bin/env perl

use strict;
use warnings;

use Tk;

my $tissue = 'plasma';

my $mw = MainWindow->new;

my $f1 = $mw->Frame()->pack;
$f1->Label(-textvariable => \$tissue)->pack;
$f1->Button(-text => 'Select Tissue', -command => sub { select_tissue(
+\$tissue) })->pack;
$f1->Button(-text => 'Quit', -command => sub { do_end(\$tissue) })->pa
+ck;

MainLoop;

sub select_tissue {
    my $tissue_ref = shift;
    # Tissue selection code here - assume 'muscle' selected
    $$tissue_ref = 'muscle';
    return;
}

sub do_end {
    my $tissue_ref = shift;
    # Print to STDOUT for demo purposes
    print "$$tissue_ref\n";
    exit;
}
[download]

Notes:

$tissue needs to be declared in a scope that's visible to the -command coderefs.
The callbacks have a reference to this variable, i.e. \$tissue.
The callbacks return nothing!
The value of $tissue is accessed or modified via $$tissue_ref.
Most widgets that have a -text option also have a -textvariable option. Here I've used a Label - it starts with the default vaue of "plasma", If you click the "Select Tissue" button, the Label text will change to "muscle".
The output (when you click "Quit") will depend on whether or not the "Select Tissue" button was pressed.

Update: fixed title s/Perk Tk/Perl Tk/

-- Ken

Comment on Re: Perl Tk - how to send a value from a subroutine back to the main program using Button Select or Download Code

Replies are listed 'Best First'.
Re^2: Perk Tk - how to send a value from a subroutine back to the main program using Button by jeri_rl (Initiate) on Jun 10, 2013 at 18:06 UTC
I am the original poster and have just joined perlmonks. Thanks so much for the advice. I have now gotten it working in the main program. Just want to be sure I am correctly understanding what is going on. You can't actually pass a value from a subroutine to the main program using a button or other widget. Instead, you create a reference to the value of interest in the main program, send that reference to the subroutine and change the reference value in the subroutine. That changed value can then be accessed from the main program. Correct?	[reply]
Re^3: Perl Tk - how to send a value from a subroutine back to the main program using Button by kcott (Archbishop) on Jun 11, 2013 at 10:21 UTC
G'day jeri_rl, Welcome to the monastery. Just to clarify, if you have something like "`... -command => sub { ... } ...`" in your code, the "`sub { ... }`" part is the callback and it cannot return anything to the main program. However, code within the callback can return values. Here's another version of my original script that does just that: #!/usr/bin/env perl use strict; use warnings; use Tk; my $tissue = 'plasma'; my $mw = MainWindow->new; my $f1 = $mw->Frame()->pack; $f1->Label(-textvariable => \$tissue)->pack; $f1->Button(-text => 'Select Tissue', -command => sub { $tissue = sele +ct_tissue() })->pack; $f1->Button(-text => 'Quit', -command => sub { do_end($tissue) })->pac +k; MainLoop; sub select_tissue { # Tissue selection code here - assume 'muscle' selected my $selected_tissue = 'muscle'; return $selected_tissue; } sub do_end { my $tissue_to_print = shift; # Print to STDOUT for demo purposes print "$tissue_to_print\n"; exit; } [download] If you run this code, you'll see it works identically to my original script. Of course, this is a very simple GUI with very straightforward subroutines. With more complex code, you can run into problems when passing values instead of references; on occasion, these can be hard to track down and rectifying them can involve reworking large parts of your code. I'd recommend references over values in this scenario. There's an added benefit of references being scalars, so you're potentially moving a lot less data around than you would with, say, `@array_with_lots_of_elements` or `%complex_data_structure`. -- Ken	[reply] [d/l] [select]
Re^4: Perl Tk - how to send a value from a subroutine back to the main program using Button by Anonymous Monk on Jun 11, 2013 at 11:00 UTC
With more complex code, you can run into problems when passing values instead of references; on occasion, these can be hard to track down and rectifying them can involve reworking large parts of your code. I'll bet half the problems come from all the closures :P	[reply]
Re^3: Perk Tk - how to send a value from a subroutine back to the main program using Button by Anonymous Monk on Jun 10, 2013 at 20:25 UTC
Yeah, see Re: Perk Tk - how to send a value from a subroutine back to the main program using Button (without MainLoop), see what MainLoop does is this `sub MainLoop { unless ($inMainLoop) { local $inMainLoop = 1; while (Tk::MainWindow->Count) { DoOneEvent(0); } } }` [download] You move the mouse, its an event (a bunch) You click a button, its an event Nothing happens for a few miliseconds, its an event If you use Tk::Wizard then each page you add, each wizard step, is like a separate MainLoop, and then returning a value can be possible (you can write procedural code), see the examples	[reply] [d/l]
Re^4: Perk Tk - how to send a value from a subroutine back to the main program using Button by jeri_rl (Initiate) on Jun 11, 2013 at 18:13 UTC
Thanks. As you can see in the thread, I've got it working using references. However, looks like I should check out Tk::Wizard. Can you recommend an introduction or tutorial? I'm afraid I find the CPAN listings only useful if you already have an idea what you are doing.	[reply]