while ( my $line = <DATA> ) {
    chomp $line;
    my @fields = qw( login      uid   gid       name           home   
+   shell );
    my @items  =
        $line =~ /^([\-\w]+):x:(\d+):(\d+):([\-\w\s\(\)\,]*):([\w\/]+)
+:([\w\/]+)$/
            or die "Malformed input [$line]";

    push @users, {};
    $users[-1]{ shift @fields } = shift @items while @fields;
}
[download]

A variation (imagine the  my $datum = shift @data is reading a file; no need to create  @fields array each time through loop; state only available with 5.10+; either version works the same):

>perl -wMstrict -MData::Dump -lE
"my @data = (
   'foo 123 %^&',  'huggle 9876 @*',   'ab 55555 !@$%^&',
   );
 ;;
 my @users;
 while (my $datum = shift @data) {
   # use constant FIELDS => qw(   alphas        digits          stuff)
+;
   state $fields = [ qw(        alphas        digits          stuff) ]
+;
   my @items = $datum =~ m{ ([[:alpha:]]+) \s+ (\d+) \s+ ([^[:alpha:]\
+d]+) }xms;
   # @{ $users[@users] }{ FIELDS() } = @items;
   @{ $users[@users] }{ @$fields } = @items;
   }
 ;;
 dd \@users;
"
[
  { alphas => "foo", digits => 123, stuff => "%^&" },
  { alphas => "huggle", digits => 9876, stuff => "\@*" },
  { alphas => "ab", digits => 55555, stuff => "!\@\$%^&" },
]
[download]

Maybe you want to collaborate with cornelius80 who seems to be working on a quite similar dataset.

Update: Also, I would seriously look at getpwent and/or Passwd instead of hand-rolling my own parser for passwd files.

Interesting, I was also thinking of yesterday's "splice/mesh" discussion. (I wouldn't really do it this way.)

But do notice in your RE, I changed delimiter and did not escape forward slashes, commas or hyphens.

use strict;
use warnings;
use List::MoreUtils qw(mesh);
use Data::Dumper;

my @users;
my @fields = qw(login uid gid name home shell);
while (<DATA>) {
    m#^\s*([\w-]+):x:(\d+):(\d+):([\w\s\(\),-]*):([\w/]+):([\w/]*)$#
      or die "Malformed input [$_]";
    push @users, { mesh @fields, @{[//]} };
}

print Dumper \@users;
__DATA__
root:x:0:0::/:/usr/bin/ksh
paul:x:201:1::/home/paul:/usr/bin/ksh
jdoe:x:202:1:John Doe:/home/jdoe:/usr/bin/ksh
[download]

Update: The parens don't need to be escaped either:

    m#^\s*([\w-]+):x:(\d+):(\d+):([\w\s(),-]*):([\w/]+):([\w/]*)$#
[download]

Or using named captures:

use strict;
use warnings;
use Data::Dumper;

my @users;
while (<DATA>) {
    m#^\s*(?<login>[\w-]+)
      :x
      :(?<uid>\d+)
      :(?<gid>\d+)
      :(?<name>[\w\s(),-]*)
      :(?<home>[\w/]+)
      :(?<shell>[\w/]*)$#x
        or die "Malformed input [$_]";
    push @users, { %+ };
}

print Dumper \@users;
__DATA__
root:x:0:0::/:/usr/bin/ksh
paul:x:201:1::/home/paul:/usr/bin/ksh
jdoe:x:202:1:John Doe:/home/jdoe:/usr/bin/ksh
[download]

If the format of the input is as fixed as in case of a passwd file, then splitting on colon makes much more sense, even if one needs to chomp in that case.

For you to judge whether this is an improvement ;)

use strict;
use warnings;
use Data::Dumper;
use List::MoreUtils qw( mesh );

my @users = map {
        { mesh 
                    @{[ qw( login uid gid name home shell ) ]}, 
                    @{[ /^([\-\w]+):x:(\d+):(\d+):([\-\w\s\(\)\,]*):([
+\w\/]+):([\w\/]+)$/ ]} }
} <DATA>;

print Dumper \@users;
__DATA__
hdb:x:1111:2222:hdb:/home/hdb:/bin/bash
[download]

UPDATE: Above is too complicated, look at this:

use strict;
use warnings;
use Data::Dumper;

my @users = map { 
  /^([\-\w]+):x:(\d+):(\d+):([\-\w\s\(\)\,]*):([\w\/]+):([\w\/]+)$/;
  { login => $1, uid => $2, gid => $3, name => $4, home => $5, shell =
+> $6 } 
} <DATA>;

print Dumper \@users;
__DATA__
hdb:x:1111:2222:hdb:/home/hdb:/bin/bash
[download]